Visual Basic 6.0

Get an SSH Tunnel's Current State (Diagnostics)

Demonstrates the Chilkat SshTunnel.GetCurrentState method, which returns an XML snapshot describing the tunnel manager, SSH channels, and current tunnel clients. It takes no arguments and is intended for diagnostics and monitoring.

Background: Because the tunnel forwards traffic on a background thread, there is no natural place in your code to observe what it is doing at a given moment. GetCurrentState provides that visibility — byte counts, active channels, and connected clients — as structured XML suited to logging or a monitoring dashboard. It is a read-only snapshot and does not affect the tunnel.

Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0

Visual Basic 6.0

Dim success As Long
success = 0

'  Demonstrates the SshTunnel.GetCurrentState method, which returns an XML snapshot describing the
'  tunnel manager, SSH channels, and current tunnel clients.  It takes no arguments and is
'  intended for diagnostics and monitoring.

Dim tunnel As New ChilkatSshTunnel

'  The tunnel forwards accepted local connections to this destination through the SSH server.
tunnel.DestHostname = "db.internal.example.com"
tunnel.DestPort = 5432

'  Connect to the SSH server.  This performs the TCP/proxy connection and SSH handshake, but
'  does not authenticate yet.
Dim sshPort As Long
sshPort = 22
success = tunnel.Connect("ssh.example.com",sshPort)
If (success = 0) Then
    Debug.Print tunnel.LastErrorText
    Exit Sub
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
Dim password As String
password = "mySshPassword"

success = tunnel.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    Debug.Print tunnel.LastErrorText
    Exit Sub
End If

'  Begin accepting so there is live tunnel state to inspect.
Dim listenPort As Long
listenPort = 1080
success = tunnel.BeginAccepting(listenPort)
If (success = 0) Then
    Debug.Print tunnel.LastErrorText
    Exit Sub
End If

'  Get a diagnostic snapshot of the tunnel's current state as XML.
Dim stateXml As String
stateXml = tunnel.GetCurrentState()
If (tunnel.LastMethodSuccess = 0) Then
    Debug.Print tunnel.LastErrorText
    Exit Sub
End If

Debug.Print stateXml

Dim waitForThreadExit As Long
waitForThreadExit = 1
success = tunnel.CloseTunnel(waitForThreadExit)
If (success = 0) Then
    Debug.Print tunnel.LastErrorText
    Exit Sub
End If