Visual Basic 6.0

Square OAuth2 Access Token

See more Square Examples

Demonstrates how to get an access token for the Square API. This example is for desktop apps only (not web apps). Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim oauth2 As New ChilkatOAuth2

' This should be the port in the localhost callback URL for your app.  
' The callback URL would look like "http://localhost:3017/" if the port number is 3017.
oauth2.ListenPort = 3017

' To use the production system, change the domains here to "connect.squareup.com"
oauth2.AuthorizationEndpoint = "https://connect.squareupsandbox.com/oauth2/authorize"
oauth2.TokenEndpoint = "https://connect.squareupsandbox.com/oauth2/token"

' Replace these with actual values.
oauth2.ClientId = "APPLICATION_ID"
oauth2.ClientSecret = "APPLICATION_SECRET"

' Make sure to include the scopes you'll need.
oauth2.Scope = "ITEMS_WRITE ITEMS_READ"

' Begin the OAuth2 three-legged flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess = 0) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' Add the session=False query param to the URL.
Dim sbUrl As New ChilkatStringBuilder
success = sbUrl.Append(url)
success = sbUrl.Append("&session=False")
' Launch this URL in the browser.
url = sbUrl.GetAsString()

' Launch the system's default browser navigated to the URL.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' Now wait for the authorization.
' We'll wait for a max of 30 seconds.
Dim numMsWaited As Long
numMsWaited = 0
Do While (numMsWaited < 30000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If there was no response from the browser within 30 seconds, then 
' the AuthFlowState will be equal to 1 or 2.
' 1: Waiting for Redirect. The OAuth2 background thread is waiting to receive the redirect HTTP request from the browser.
' 2: Waiting for Final Response. The OAuth2 background thread is waiting for the final access token response.
' In that case, cancel the background task started in the call to StartAuth.
If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    Debug.Print "No response from the browser!"
    Exit Sub
End If

' Check the AuthFlowState to see if authorization was granted, denied, or if some error occurred
' The possible AuthFlowState values are:
' 3: Completed with Success. The OAuth2 flow has completed, the background thread exited, and the successful JSON response is available in AccessTokenResponse property.
' 4: Completed with Access Denied. The OAuth2 flow has completed, the background thread exited, and the error JSON is available in AccessTokenResponse property.
' 5: Failed Prior to Completion. The OAuth2 flow failed to complete, the background thread exited, and the error information is available in the FailureInfo property.
If (oauth2.AuthFlowState = 5) Then
    Debug.Print "OAuth2 failed to complete."
    Debug.Print oauth2.FailureInfo
    Exit Sub
End If

If (oauth2.AuthFlowState = 4) Then
    Debug.Print "OAuth2 authorization was denied."
    Debug.Print oauth2.AccessTokenResponse
    Exit Sub
End If

If (oauth2.AuthFlowState <> 3) Then
    Debug.Print "Unexpected AuthFlowState:" & oauth2.AuthFlowState
    Exit Sub
End If

Debug.Print "OAuth2 authorization granted!"
Debug.Print "Access Token = " & oauth2.AccessToken

' Get the full JSON response:
Dim json As New ChilkatJsonObject
success = json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = 0

' The JSON response looks like this:

' {
'   "access_token": "EAAAE...depV",
'   "token_type": "bearer",
'   "expires_at": "2020-09-04T23:30:18Z",
'   "merchant_id": "MLQA83866KSR5",
'   "refresh_token": "EQAAEE...jeVfD6MV"
' }

Debug.Print json.Emit()

' Save the JSON to a file for future requests.
Dim fac As New CkFileAccess
success = fac.WriteEntireTextFile("qa_data/tokens/square.json",json.Emit(),"utf-8",0)