Visual Basic 6.0

Find Certificate for Email Encryption

Demonstrates finding the recipient's certificate in the Windows certificate store and using it to send encrypted email. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim mailman As New ChilkatMailMan

' Set the SMTP server.
mailman.SmtpHost = "smtp.example.com"

' Create a new email object
Dim email As New ChilkatEmail

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Joe <joe@example.com>"
' Emails are encrypted using the recipient's certificate.
Dim recipientEmailAddr As String
recipientEmailAddr = "jane@example2.com"
success = email.AddTo("Jane",recipientEmailAddr)

' Indicate that the email is to be sent encrypted.
email.SendEncrypted = 1

' This example demonstrates finding the email encryption certificate
' on a Windows system where the certificate is stored in the Windows 
' certificate store.

Dim cert As New ChilkatCert
' The recipient's certificate is used to encrypt.
' (Because the recipient is the only one in possession of the private key to decrypt.)
success = cert.LoadByEmailAddress(recipientEmailAddr)
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Specify the certificate to be used for encryption.
success = email.SetEncryptCert(cert)

success = mailman.SendEmail(email)
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
Else
    Debug.Print "Encrypted Mail Sent!"
End If