Visual Basic 6.0

Retrieve a Particular SharePoint List as XML

See more SharePoint Examples

Downloads a particular SharePoint list and parses the XML. Visual Basic 6.0

Dim success As Long
success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' -------------------------------------------------------------------------
' The following comments apply to SharePoint Windows classic authentication.
' -------------------------------------------------------------------------
' For example, imagine our SharePoint endpoint is https://xyzoffice.mycompany.com/
' The SHAREPOINT_NTLM_DOMAIN would be "mycompany.com"
' The SHAREPOINT_HTTPS_DOMAIN would be "xyzoffice.mycompany.com"
' Also, the SHAREPOINT_USERNAME would be just the name, not a full email address.
' for example, "chilkat" instead of "chilkat@mycompany.com"

Dim http As New ChilkatHttp

' If SharePoint Windows classic authentication is used, then set the 
' Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = 1

' -------------------------------------------------------------------------
' The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
' If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
' establish the cookie as shown at SharePoint Online Authentication
' -------------------------------------------------------------------------

' Indicate that we want an XML reply
http.Accept = "application/atom+xml"
http.AcceptCharset = "utf-8"

' The contents of a SharePoint list can be downloaded by it's URI,
' which has the following URL format:
' https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/items
' 
' To get the URI's for all SharePoint lists, 
' See Get SharePoint Lists.

' Download the list like this (where the SHAREPOINT_DOCUMENTS_GUID is replaced with the actual GUID)
Dim sbXml As New ChilkatStringBuilder
success = http.QuickGetSb("https://SHAREPOINT_HTTPS_DOMAIN/_api/Web/Lists(guid'SHAREPOINT_DOCUMENTS_GUID')/items",sbXml)
If (success <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim xml As New ChilkatXml
success = xml.LoadSb(sbXml,1)

Dim sbBase As New ChilkatStringBuilder
success = sbBase.Append(xml.GetAttrValue("xml:base"))
Debug.Print "Base URL = " & sbBase.GetAsString()

' Find the number of entries in this list.
Dim numEntries As Long
numEntries = xml.NumChildrenHavingTag("entry")
Debug.Print "Number of Entries in this SharePoint List = " & numEntries

Dim sbUri As New ChilkatStringBuilder

Dim i As Long
i = 0
Do While i < numEntries
    xml.I = i

    Dim title As String
    title = xml.GetChildContent("entry[i]|content|m:properties|d:Title")

    success = sbUri.SetString(sbBase.GetAsString())
    success = sbUri.Append(xml.GetChildContent("entry[i]|id"))

    Debug.Print (i + 1) & ": " & title
    Debug.Print "URI: " & sbUri.GetAsString()

    i = i + 1
Loop

' The output of this program (when I ran w/ my test SharePoint data) looks something like this:

' I found that not every item has a Title,  but as viewed in a browser, I can see each of the item's name.
' (The number of items agrees with what I can interactively see in a browser.) The mystery of what
' is being shown for the name (or title) in the browser will be investigated further as Chilkat
' continues to explore the SharePoint API...

' 	Base URL = https://xyzoffice.mycompany.com/_api/
' 	Number of Entries in this SharePoint List = 13
' 	1: Domain Name created for Exchange Docx
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(3)
' 	2: 
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(4)
' 	3: VCAC_RA_Design.docx
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(5)
' 	4: 
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(9)
' 	5: 
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(10)
' 	6: Architecture Briefv1
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(16)
' 	7: PowerPoint Presentation
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(17)
' 	8: 
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(18)
' 	9: 
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(19)
' 	10: 
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(20)
' 	11: FRC Summit Brief
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(21)
' 	12: VCAC DISA Brief 8-13-16
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(22)
' 	13: TEST PROCEDURE
' 	URI: https://xyzoffice.mycompany.com/_api/Web/Lists(guid'xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx')/Items(23)
' 
'