Visual Basic 6.0

SharePoint -- Check In a File

In SharePoint, you can check out a file to make sure nobody can change it before you update it. After updating, you can check in the file. This example shows how to check in a SharePoint file. Visual Basic 6.0

Dim success As Long
success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' If SharePoint Windows classic authentication is used, then set the 
' Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = 1

' The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
' If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
' establish the cookie as shown at SharePoint Online Authentication

' This example will check in the file named "penguins2.jpg" 
' which is located in the "/Documents" folder.

Dim req As New ChilkatHttpRequest
req.HttpVerb = "POST"
' Note that our path uses GetFileByServerRelativeUrl and not GetFolderByServerRelativeUrl
' Also, if your Sharepoint site is within a site collection, the URL is formatted like this (where "teamA" is the name of the site)
' /sites/teamA/_api/web/GetFileByServerRelativeUrl('/sites/teamA/Documents/penguins2.jpg')/CheckIn(comment='Comment',checkintype=0)
req.Path = "/_api/web/GetFileByServerRelativeUrl('/Documents/penguins2.jpg')/CheckIn(comment='Comment',checkintype=0)"

' We need to add a form digest value in the X-RequestDigest header field.
' See this example for details on
' how to get (and cache) a form digest value
req.AddHeader "X-RequestDigest","SHAREPOINT_FORM_DIGEST"

' Send the POST using HTTPS (TLS). Port 443 is the default port for https.
Dim bUseTls As Long
bUseTls = 1
Dim resp As New ChilkatHttpResponse
success = http.HttpSReq("SHAREPOINT_HTTPS_DOMAIN",443,bUseTls,req,resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' The response body contains XML.
Dim xml As New ChilkatXml
success = xml.LoadXml(resp.BodyStr)

If (resp.StatusCode <> 200) Then
    Debug.Print "Response status code = " & resp.StatusCode
    Debug.Print xml.GetXml()
    Debug.Print "Failed"
    Exit Sub
End If

' Show the successful XML response.
Debug.Print xml.GetXml()
Debug.Print "Success."

' A successful XML response looks like this:
' <?xml version="1.0" encoding="utf-8" ?>
' <d:CheckIn xmlns:d="http://schemas.microsoft.com/ado/2007/08/dataservices" 	
' 	xmlns:m="http://schemas.microsoft.com/ado/2007/08/dataservices/metadata"
' 	xmlns:georss="http://www.georss.org/georss" 
' 	xmlns:gml="http://www.opengis.net/gml" m:null="true" />
'