Visual Basic 6.0

SFTP Upload from Local Filesystem

See more SFTP Examples

Demonstrates how to upload a file to an SSH server. There are no limitations on file size, and the file is streamed directly from the local filesystem. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim sftp As New ChilkatSFtp

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
Dim hostname As String
hostname = "sftp.example.com"
Dim port As Long
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

' After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

' Open a file for writing on the SSH server.
' If the file already exists, it is overwritten.
' (Specify "createNew" instead of "createTruncate" to
' prevent overwriting existing files.)
Dim handle As String
handle = sftp.OpenFile("hamlet.xml","writeOnly","createTruncate")
If (sftp.LastMethodSuccess <> 1) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

' Upload from the local file to the SSH server.
success = sftp.UploadFile(handle,"c:/temp/hamlet.xml")
If (success <> 1) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

' -----------------------------------------------------------------------------
' This is important.  You must close the handle on the server.
' Otherwise open handles will accumulate on the server until eventually a limit
' is reached and the server will fail on a call to OpenFile.
' -----------------------------------------------------------------------------

' Close the file.
success = sftp.CloseHandle(handle)
If (success <> 1) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

Debug.Print "Success."