Visual Basic 6.0

Download from an SFTP Server Using an Open Handle

Demonstrates the Chilkat SFtp.DownloadFile method, which streams a remote file identified by an open handle to a local path. The first argument is the handle (from OpenFile) and the second is the local file path. Close the handle with CloseHandle when done.

Note: This example uses relative local paths, which are resolved against the application's current working directory. Absolute local paths may also be used. Supply the paths appropriate to your own environment.

Background: The handle-based counterpart to DownloadFileByName. Opening the file yourself lets you set read options — such as requesting exclusive read access — that the convenience method does not expose, and it separates the open step from the transfer so the handle can be used for more than one operation. As with any handle, close it when finished to release the server-side resource.

Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0

Visual Basic 6.0

Dim success As Long
success = 0

'  Demonstrates the SFtp.DownloadFile method, which streams a remote file identified by an open
'  handle to a local path.  The 1st argument is the handle and the 2nd is the local file path.

Dim sftp As New ChilkatSFtp

'  Connect, authenticate, and initialize the SFTP subsystem.
Dim port As Long
port = 22
success = sftp.Connect("sftp.example.com",port)
If (success = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
Dim password As String
password = "mySshPassword"

success = sftp.AuthenticatePw("mySshLogin",password)
If (success = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

success = sftp.InitializeSftp()
If (success = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

'  Open the remote file for reading.  OpenFile returns a handle string.
Dim handle As String
handle = sftp.OpenFile("subdir/report.pdf","readOnly","openExisting")
If (sftp.LastMethodSuccess = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

'  Stream the remote file to the local filesystem.  The transfer is not limited by memory.
success = sftp.DownloadFile(handle,"qa_output/report.pdf")
If (success = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

'  Close the remote handle when the download is complete.
success = sftp.CloseHandle(handle)
If (success = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

Debug.Print "Downloaded."

sftp.Disconnect