Visual Basic 6.0

REST Download Binary to Memory (Byte Array) (Amazon S3)

See more Amazon S3 (new) Examples

Demonstrates how to make a REST call that returns a binary response body. This example is valid for reasonably small files that fit in memory. The example shows how to download a small JPG from the Amazon S3 service. For larger files, Chilkat provides streaming functionality to stream directly to a file, or to make an asynchronous call where the foreground thread can read the response body stream. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New ChilkatRest

' Connect to the Amazon AWS REST server.
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("s3.amazonaws.com",port,bTls,bAutoReconnect)

' ----------------------------------------------------------------------------
' Important: For buckets created in regions outside us-east-1,
' there are three important changes that need to be made.
' See Working with S3 Buckets in Non-us-east-1 Regions for the details.
' ----------------------------------------------------------------------------

' Provide AWS credentials for the REST call.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkat100".
rest.Host = "chilkat100.s3.amazonaws.com"

' Send the request to download the JPG.
success = rest.SendReqNoBody("GET","/starfish.jpg")
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' Read the response header.
Dim responseStatusCode As Long
responseStatusCode = rest.ReadResponseHeader()
If (responseStatusCode < 0) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Debug.Print "Response status code = " & responseStatusCode

' We expect a 200 response status if the JPG data is coming.
' Otherwise, we'll get a string response body with an error message(or no response body).
If (responseStatusCode = 200) Then
    Dim jpgData() As Byte
    jpgData = rest.ReadRespBodyBinary()
    If (rest.LastMethodSuccess <> 1) Then
        Debug.Print rest.LastErrorText
    Else
        Debug.Print "Successfully received the JPG bytes.."
    End If

Else
    Dim errResponse As String
    errResponse = rest.ReadRespBodyString()
    If (rest.LastMethodSuccess <> 1) Then
        Debug.Print rest.LastErrorText
    Else
        Debug.Print errResponse
    End If

End If