Visual Basic 6.0

Rabobank Refresh OAuth2 Access Token

See more OAuth2 Examples

Demonstrates how to refresh an expired Rabobank OAuth2 access token. (No interactive user interaction is required to refresh an access token.) Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' We previously obtained an access token and saved the JSON to a file using this example:
' Get Rabobank OAuth2 Access Token

Dim json As New ChilkatJsonObject
success = json.LoadFile("qa_data/tokens/rabobank.json")
If (success <> 1) Then
    Exit Sub
End If

' {
'   "token_type": "Bearer",
'   "access_token": "AAIkYTU0ZWM ... sxE0KL0HHWw",
'   "expires_in": 3600,
'   "consented_on": 1584641121,
'   "scope": "ais.balances.read ais.transactions.read-90days ais.transactions.read-history",
'   "refresh_token": "AAJXXSdN ... Uiblz9ILkxNBlytRGA",
'   "refresh_token_expires_in": 157784760,
'   "expires_on": "1584644722"
' }

' Refresh the access token by sending a POST like this:
' 

' POST /oauth2/token
' Headers:
'     Content-Type: application/x-www-form-urlencoded
'     Authorization: Basic BASE64(CLIENT_ID + ":" + CLIENT_SECRET)
' 
' Body (x-www-form-urlencoded):
'     grant_type: refresh_token
'     refresh_token: REFRESH_TOKEN

Dim req As New ChilkatHttpRequest
req.AddParam "grant_type","refresh_token"
req.AddParam "refresh_token",json.StringOf("refresh_token")

Dim http As New ChilkatHttp

' Causes the "Authorization: Basic BASE64(CLIENT_ID + ":" + CLIENT_SECRET)" header to be added..
http.BasicAuth = 1
http.Login = "YOUR_APP_CLIENT_ID"
http.Password = "YOUR_APP_CLIENT_SECRET"

req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

Dim resp As New ChilkatHttpResponse
success = http.HttpReq("https://api-sandbox.rabobank.nl/openapi/sandbox/oauth2/token",req,resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Load the JSON response.
success = json.Load(resp.BodyStr)
json.EmitCompact = 0

' Show the JSON response.
Debug.Print json.Emit()

Debug.Print "Response status code: " & resp.StatusCode

' If the response status code is not 200, then it's an error.
If (resp.StatusCode <> 200) Then
    Exit Sub
End If

' Save the refreshed access token JSON to a file for future requests.
Dim fac As New CkFileAccess
success = fac.WriteEntireTextFile("qa_data/tokens/rabobank.json",json.Emit(),"utf-8",0)