Chilkat Examples

ChilkatHOMEAndroid™Classic ASPCC++C#Mono C#.NET Core C#C# UWP/WinRTDataFlexDelphi ActiveXDelphi DLLVisual FoxProJavaLianjaMFCObjective-CPerlPHP ActiveXPHP ExtensionPowerBuilderPowerShellPureBasicCkPythonChilkat2-PythonRubySQL ServerSwift 2Swift 3,4,5...TclUnicode CUnicode C++Visual Basic 6.0VB.NETVB.NET UWP/WinRTVBScriptXojo PluginNode.jsExcelGo

Visual Basic 6.0 Web API Examples

Primary Categories

ABN AMRO
AWS Translate
Activix CRM
Adyen
Amazon DynamoDB
Amazon MWS
Amazon Rekognition
Aruba Fatturazione
Azure Maps
Azure Monitor
Azure OAuth2
Azure Storage Accounts
Bitfinex v2 REST
Bluzone
CallRail
CardConnect
Cerved
ClickBank
Clickatell
Cloudfare
Constant Contact
DocuSign
ETrade
Egypt ITIDA
Etsy
Facebook
Frame.io
GeoOp
GetHarvest
Global Payments
Google People
Google Search Console
Hungary NAV Invoicing
IBM Text to Speech
Ibanity
IntakeQ
Jira
Lightspeed
MYOB
Magento
Mailgun
MedTunnel
MercadoLibre
Microsoft Calendar

Microsoft Group
Microsoft Tasks and Plans
Microsoft Teams
Okta OAuth/OIDC
OneLogin OIDC
OneNote
PRODA
PayPal
Paynow.pl
Peoplevox
Populi
QuickBooks
Rabobank
Royal Mail OBA
SCiS Schools Catalogue
SII Chile
SMSAPI
SOAP finkok.com
SendGrid
Shippo
Shopify
Shopware
Shopware 6
SimpleTexting
Square
Stripe
SugarCRM
TicketBAI
Trello
Twilio
Twitter
UniPin
VoiceBase
Vonage
Walmart
Walmart v3
WhatsApp
WiX
WooCommerce
WordPress
Xero
Yousign
Zoom
_Miscellaneous_
eBay
effectconnect
hacienda.go.cr

 

 

 

(Visual Basic 6.0) Quickbooks OAuth2 in a Desktop App

Demonstrates how to get a QuickBooks OAuth2 access token from a desktop application or script.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example is for desktop applicatons (it is not for code that runs on a web server).
' You'll need to add a line (or a few lines of code) to popup a web browser that navigates to a URL.
' This is explained in the comments below.

' This is the way to initially obtain the OAuth2 access token.  Afterwards it can be 
' repeatedly refreshed without user interaction, as shown in this example: Refresh Quickbooks OAuth2 Access Token.

Dim oauth2 As New ChilkatOAuth2
Dim success As Long

' QuickBooks OAuth2 allows for an "http://localhost:<portNumber>/" callback URL for sandbox testing,
' but not for production.
' For a desktop app, you must provide a script on your web server to redirect to "http://localhost/<portNumber>"
' It can be written in C#, PHP, or whatever desired.  It must include the query string in the redirection.
' For example, in PHP your script would look like this:

' <?php
'   header( 'Location: http://localhost:3017?' . $_SERVER['QUERY_STRING'] );
' ?>

oauth2.AppCallbackUrl = "https://yourwebserver.com/OAuth2.php"
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://appcenter.intuit.com/connect/oauth2"
oauth2.TokenEndpoint = "https://oauth.platform.intuit.com/oauth2/v1/tokens/bearer"

' Replace these with actual values.
oauth2.ClientId = "QUICKBOOKS-CLIENT-ID"
oauth2.ClientSecret = "QUICKBOOKS-CLIENT-SECRET"
oauth2.UseBasicAuth = 1
oauth2.CodeChallenge = 0

' Indicate the desired access.  Possible scopes that can appear in the list are:
' com.intuit.quickbooks.accounting:  QuickBooks Online API
' com.intuit.quickbooks.payment:  QuickBooks Payments API
' openid:  OpenID Connect processing
' profile:  user's given and family names
' email:  user's email address
' phone:  user's phone number
' address:  user's physical address
oauth2.Scope = "com.intuit.quickbooks.accounting"

' Begin the OAuth2 three-legged flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> 1) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

Debug.Print "url = " & url

' At this point, your application should load the URL in a browser.
' For example, 
' in C#: System.Diagnostics.Process.Start(url);
' in Java: Desktop.getDesktop().browse(new URI(url));
' in VBScript: Set wsh=WScript.CreateObject("WScript.Shell")
'              wsh.Run url
' in Xojo: ShowURL(url)  (see http://docs.xojo.com/index.php/ShowURL)
' in Dataflex: Runprogram Background "c:\Program Files\Internet Explorer\iexplore.exe" sUrl
' in dBASE: run(false, 'rundll32 url.dll,FileProtocolHandler "' + lcUrl + '"')
' The QuickBooks account owner would interactively accept or deny the authorization request.

' Add the code to load the url in a web browser here...
' Add the code to load the url in a web browser here...
' Add the code to load the url in a web browser here...

' Now wait for the authorization.
' We'll wait for a max of 60 seconds.
Dim numMsWaited As Long
numMsWaited = 0
Do While (numMsWaited < 60000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If there was no response from the browser within 60 seconds, then 
' the AuthFlowState will be equal to 1 or 2.
' 1: Waiting for Redirect. The OAuth2 background thread is waiting to receive the redirect HTTP request from the browser.
' 2: Waiting for Final Response. The OAuth2 background thread is waiting for the final access token response.
' In that case, cancel the background task started in the call to StartAuth.
If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    Debug.Print "No response from the browser!"
    Exit Sub
End If

' Check the AuthFlowState to see if authorization was granted, denied, or if some error occurred
' The possible AuthFlowState values are:
' 3: Completed with Success. The OAuth2 flow has completed, the background thread exited, and the successful JSON response is available in AccessTokenResponse property.
' 4: Completed with Access Denied. The OAuth2 flow has completed, the background thread exited, and the error JSON is available in AccessTokenResponse property.
' 5: Failed Prior to Completion. The OAuth2 flow failed to complete, the background thread exited, and the error information is available in the FailureInfo property.
If (oauth2.AuthFlowState = 5) Then
    Debug.Print "OAuth2 failed to complete."
    Debug.Print oauth2.FailureInfo
    Exit Sub
End If

If (oauth2.AuthFlowState = 4) Then
    Debug.Print "OAuth2 authorization was denied."
    Debug.Print oauth2.AccessTokenResponse
    Exit Sub
End If

If (oauth2.AuthFlowState <> 3) Then
    Debug.Print "Unexpected AuthFlowState:" & oauth2.AuthFlowState
    Exit Sub
End If

' Save the full JSON access token response to a file.
Dim sbJson As New ChilkatStringBuilder
success = sbJson.Append(oauth2.AccessTokenResponse)
success = sbJson.WriteFile("qa_data/tokens/qb-access-token.json","utf-8",0)

' The full JSON received looks like this:
' {
'   "expires_in": 3600,
'   "x_refresh_token_expires_in": 8726400,
'   "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
'   "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
'   "token_type": "bearer"
' }

Debug.Print "OAuth2 authorization granted!"
Debug.Print "Access Token = " & oauth2.AccessToken

 

© 2000-2021 Chilkat Software, Inc. All Rights Reserved.