Visual Basic 6.0

Duplicate OpensSSL to Create Signature using Cert and Key Files

See more OpenSSL Examples

This example duplicates the following:

openssl smime –sign -in something.xml -out something.der -signer mycert.crt -inkey cert.key -outform der –nodetach

Note: Although "smime" is the OpenSSL command, it's not actually producing S/MIME. The arguments "-outform der -binary" indicates that the output is binary DER (i.e. the PKCS7 binary signature). The input can be any type of file: XML, PDF, JPG, ... *anything*...

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

' Load the cert and private key from separate files.
Dim cert As New ChilkatCert
success = cert.LoadFromFile("myCert.crt")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

Dim bd As New ChilkatBinData
success = bd.LoadFile("cert.key")
Dim privkey As New PrivateKey
' Load from any format private key.
' If the file does not need a password, the 2nd arg is ignored.
success = privkey.LoadAnyFormat(bd,"password_if_needed")
If (success <> 1) Then
    Debug.Print privkey.LastErrorText
    Exit Sub
End If

success = crypt.SetSigningCert2(cert,privkey)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Create the opaque signature (PKCS7 binary DER that contains both the signature and original file data).
success = crypt.CreateP7M("qa_data/infile.anything","qa_output/outfile.der")
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Success."