Visual Basic 6.0

Duplicate OpensSSL to Sign File and Output Binary DER

See more OpenSSL Examples

This example duplicates the following:

openssl smime -sign -in INPUT.xml -signer SIGN.PEM -passin pass:MYPASS -outform der -binary -nodetach -out SIGNED.P7M

Note: Although "smime" is the OpenSSL command, it's not actually producing S/MIME. The arguments "-outform der -binary" indicates that the output is binary DER (i.e. the PKCS7 binary signature). The input can be any type of file: XML, PDF, JPG, ... *anything*...

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

' Load the PEM containing cert + private key.
Dim pem As New ChilkatPem
success = pem.LoadPemFile("qa_data/pem/myPem.pem","password")
If (success = 0) Then
    Debug.Print pem.LastErrorText
    Exit Sub
End If

Dim privkey As New PrivateKey
success = pem.PrivateKeyAt(0,privkey)
If (success = 0) Then
    Debug.Print pem.LastErrorText
    Exit Sub
End If

Dim cert As New ChilkatCert
success = pem.CertAt(0,cert)
If (success = 0) Then
    Debug.Print pem.LastErrorText
    Exit Sub
End If

success = crypt.SetSigningCert2(cert,privkey)
If (success = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Alternatively, we could use a .pfx/.p12 file.
' (Chilkat also supports other formats/sources for cert/private keys...)
Dim certFromP12 As New ChilkatCert
success = certFromP12.LoadPfxFile("qa_data/p12/myP12.p12","password")
If (success = 0) Then
    Debug.Print certFromP12.LastErrorText
    Exit Sub
End If

' The certificate, when loaded from a .pfx/.p12, will automatically 
' include the associated private key, assuming it's present in the .p12.
' We don't have to explicitly provide the private key as in the
' lines of code above that use the PEM file.
success = crypt.SetSigningCert(certFromP12)
If (success = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Create the opaque signature (PKCS7 binary DER that contains both the signature and original file data).
success = crypt.CreateP7M("qa_data/infile.anything","qa_output/outfile.p7m")
If (success = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Success."