Visual Basic 6.0

Create a multipart/alternative MIME Entity

Demonstrates the Chilkat Mime.NewMultipartAlternative method, which initializes the object as an empty multipart/alternative entity. It takes no arguments; the alternative representations are then appended.

Background: multipart/alternative holds several renderings of the same content and lets the client pick the best one it can display — the standard way to send an email as both plain text and HTML. Order matters: parts go from least to most preferred, so the plain-text version comes first and the HTML last, and a client shows the last one it understands.

Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0

Visual Basic 6.0

Dim success As Long
success = 0

'  Demonstrates the Mime.NewMultipartAlternative method, which initializes the object as an empty
'  multipart/alternative entity, clearing any existing content.  It takes no arguments.

Dim mime As New ChilkatMime

success = mime.NewMultipartAlternative()
If (success = 0) Then
    Debug.Print mime.LastErrorText
    Exit Sub
End If

'  multipart/alternative holds two representations of the SAME content; the client displays the
'  last one it can render.  Add a plain-text part, then an HTML part.
Dim textPart As New ChilkatMime
success = textPart.SetBodyFromPlainText("Hello (plain text version).")
If (success = 0) Then
    Debug.Print textPart.LastErrorText
    Exit Sub
End If

success = mime.AppendPart(textPart)
If (success = 0) Then
    Debug.Print mime.LastErrorText
    Exit Sub
End If

Dim htmlPart As New ChilkatMime
success = htmlPart.SetBodyFromHtml("<html><body><b>Hello</b> (HTML version).</body></html>")
If (success = 0) Then
    Debug.Print htmlPart.LastErrorText
    Exit Sub
End If

success = mime.AppendPart(htmlPart)
If (success = 0) Then
    Debug.Print mime.LastErrorText
    Exit Sub
End If

Debug.Print "Number of alternatives: " & mime.NumParts