Visual Basic 6.0

Fetch All Messages from a POP3 Mailbox

Demonstrates the Chilkat MailMan.FetchAll method, which retrieves messages from the POP3 mailbox and appends them to an EmailBundle. The arguments are keepOnServer, headersOnly, numBodyLines, and the EmailBundle that receives the emails. This example downloads every message and iterates the bundle, printing each subject.

Background: An EmailBundle is Chilkat's container for a set of downloaded messages — you read its MessageCount and pull out each Email with EmailAt. The three flags control how much is fetched: keepOnServer leaves copies in the mailbox rather than removing them, headersOnly downloads just the headers for a fast preview, and numBodyLines can fetch a partial body (0 means the whole body). Traditional POP3 clients download and delete; setting keepOnServer to true supports "leave mail on server" behavior.

Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0

Visual Basic 6.0

Dim success As Long
success = 0

'  Demonstrates the MailMan.FetchAll method, which retrieves messages from the POP3 mailbox
'  and appends them to an EmailBundle.  The arguments are keepOnServer, headersOnly,
'  numBodyLines, and the EmailBundle that receives the emails.

Dim mailman As New ChilkatMailMan

'  Configure the POP3 server connection.
mailman.MailHost = "pop.example.com"
mailman.MailPort = 995
mailman.PopSsl = 1
mailman.PopUsername = "user@example.com"
mailman.PopPassword = "myPassword"

'  Fetch all messages, leaving them on the server, with full bodies.
'  keepOnServer=1, headersOnly=0 (fetch the entire message).
'  Note: numBodyLines only applies when headersOnly is 1 (it sets how many lines of the
'  body to include along with the headers).  When headersOnly is 0, the entire message
'  is fetched and numBodyLines is ignored.
Dim bundle As New ChilkatEmailBundle

success = mailman.FetchAll(1,0,0,bundle)
If (success = 0) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

Dim n As Long
n = bundle.MessageCount
Debug.Print "Fetched " & n & " messages."

Dim email As New ChilkatEmail
Dim i As Long
For i = 0 To n - 1
    success = bundle.EmailAt(i,email)
    Debug.Print email.Subject
Next

'  Note: Explicitly connecting/authenticating is optional.  Chilkat MailMan automatically
'  connects and authenticates -- using the property settings above -- whenever a server
'  operation requires it.  Calling the explicit connect/authenticate methods can still be
'  helpful to determine whether a failure occurs while connecting or while authenticating.