Visual Basic 6.0

Verify JWT Using an ECC Public Key (ES256, ES384, ES512)

See more JSON Web Token (JWT) Examples

Demonstrates how to verify a JWT that was signed using an ECC private key.

This example verifies the ECC signature. It also does the following:

• Checks to see if the time constraints ("nbf" and "exp") are valid.
• Recovers the original JOSE header.
• Recovers the original claims JSON.

Visual Basic 6.0

Dim success As Long
success = 0

' Demonstrates how to verify an JWT using an ECC public key.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim pubKey As New PublicKey
success = pubKey.LoadFromFile("qa_data/pem/ecc_public.pem")

Dim jwt As New ChilkatJwt

Dim token As String
token = "eyJhbGciOiJFUzI1NiIsInR5cCI6IkpXVCJ9.eyJpc3MiOiJodHRwOi8vZXhhbXBsZS5vcmciLCJzdWIiOiJKb2huIiwiYXVkIjoiaHR0cDovL2V4YW1wbGUuY29tIiwiaWF0IjoxNDg1NzA4NzkyLCJuYmYiOjE0ODU3MDg3OTIsImV4cCI6MTQ4NTcxMjM5Mn0.wqsuyJpxJ073ox-lOiLFqG1lQocXe4hGf2XGZJRrO3qn0UusxI_bu3Gzky8gBsH4sA4u9TWZn5M-1wYMMIJk6Q"

' First verify the signature.
Dim sigVerified As Long
sigVerified = jwt.VerifyJwtPk(token,pubKey)
Debug.Print "verified: " & sigVerified

' Let's see if the time constraints, if any, are valid.
' The above JWT was created on the afternoon of 16-May-2016, with an expiration of 1 hour.
' If the current system time is before the "nbf" time, or after the "exp" time,
' then IsTimeValid will return false/0.
' Also, we'll allow a leeway of 60 seconds to account for any clock skew.
' Note: If the token has no "nbf" or "exp" claim fields, then IsTimeValid is always true.
Dim leeway As Long
leeway = 60
Dim bTimeValid As Long
bTimeValid = jwt.IsTimeValid(token,leeway)
Debug.Print "time constraints valid: " & bTimeValid

' Now let's recover the original claims JSON (the payload).
Dim payload As String
payload = jwt.GetPayload(token)
' The payload will likely be in compact form:
Debug.Print payload

' We can format for human viewing by loading it into Chilkat's JSON object
' and emit.
Dim json As New ChilkatJsonObject
success = json.Load(payload)
json.EmitCompact = 0
Debug.Print json.Emit()

' We can recover the original JOSE header in the same way:
Dim joseHeader As String
joseHeader = jwt.GetHeader(token)
' The payload will likely be in compact form:
Debug.Print joseHeader

' We can format for human viewing by loading it into Chilkat's JSON object
' and emit.
success = json.Load(joseHeader)
json.EmitCompact = 0
Debug.Print json.Emit()