Visual Basic 6.0

Create JWT Using ECC (ES256, ES384, or ES512)

See more JSON Web Token (JWT) Examples

Demonstrates how to create a JWT using an ECC private key. This is for JOSE headers with an "alg" of ES256, ES384, or ES512. When ECC is used, the private key signs (creates) the JWT, and the public key is for verification.

This example also demonstrates how to include time constraints:

• nbf: Not Before Time
• exp: Expiration Time
• iat: Issue At Time

Visual Basic 6.0

Dim success As Long
success = 0

' Demonstrates how to create a JWT using an ECC private key.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim privKey As New PrivateKey

' Load an ECC private key from a PEM file.
success = privKey.LoadPemFile("qa_data/pem/ecc_privKey.pem")
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim jwt As New ChilkatJwt

' Build the JOSE header
Dim jose As New ChilkatJsonObject
' Use ES256.  Pass the string "ES384" or "ES512" to use ECC with SHA-384 or SHA-512.
success = jose.AppendString("alg","ES256")
success = jose.AppendString("typ","JWT")

' Now build the JWT claims (also known as the payload)
Dim claims As New ChilkatJsonObject
success = claims.AppendString("iss","http://example.org")
success = claims.AppendString("sub","John")
success = claims.AppendString("aud","http://example.com")

' Set the timestamp of when the JWT was created to now.
Dim curDateTime As Long
curDateTime = jwt.GenNumericDate(0)
success = claims.AddIntAt(-1,"iat",curDateTime)

' Set the "not process before" timestamp to now.
success = claims.AddIntAt(-1,"nbf",curDateTime)

' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1,"exp",curDateTime + 3600)

' Produce the smallest possible JWT:
jwt.AutoCompact = 1

' Create the JWT token.  This is where the ECC signature is created.
Dim token As String
token = jwt.CreateJwtPk(jose.Emit(),claims.Emit(),privKey)

Debug.Print token

' Example output:
' eyJhbGciOiJFUzI1NiIsInR5cCI6IkpXVCJ9.eyJpc3MiOiJodHRwOi8vZXhhbXBsZS5vcmciLCJzdWIiOiJKb2huIiwiYXVkIjoiaHR0cDovL2V4YW1wbGUuY29tIiwiaWF0IjoxNDg1NzA4NzkyLCJuYmYiOjE0ODU3MDg3OTIsImV4cCI6MTQ4NTcxMjM5Mn0.wqsuyJpxJ073ox-lOiLFqG1lQocXe4hGf2XGZJRrO3qn0UusxI_bu3Gzky8gBsH4sA4u9TWZn5M-1wYMMIJk6Q