Visual Basic 6.0

JSON: Array of Objects

See more JSON Examples

Here we have a JSON object that contains an array, where each element in the array is a JSON object. This example demonstrates how to access the objects contained within an array.

{ 
  "employees":[
    {"firstName":"John", "lastName":"Doe"},
    {"firstName":"Anna", "lastName":"Smith"},
    {"firstName":"Peter","lastName":"Jones"}
  ]
}

Visual Basic 6.0

Dim success As Long
success = 0

Dim json As New ChilkatJsonObject

' This is the above JSON with whitespace chars removed (SPACE, TAB, CR, and LF chars).
' The presence of whitespace chars for pretty-printing makes no difference to the Load
' method. 
Dim jsonStr As String
jsonStr = "{""employees"":[{""firstName"":""John"", ""lastName"":""Doe""},{""firstName"":""Anna"", ""lastName"":""Smith""},{""firstName"":""Peter"",""lastName"":""Jones""}]}"

success = json.Load(jsonStr)
If (success <> 1) Then
    Debug.Print json.LastErrorText
    Exit Sub
End If

' Get the "employees" array.
Dim employees As ChilkatJsonArray
Set employees = json.ArrayOf("employees")
If (json.LastMethodSuccess = 0) Then
    Debug.Print "employees member not found."
    Exit Sub
End If

' Iterate over each employee, getting the JSON object at each index.
Dim numEmployees As Long
numEmployees = employees.Size
Dim i As Long
i = 0
Do While i < numEmployees

    Dim empObj As ChilkatJsonObject
    Set empObj = employees.ObjectAt(i)

    Debug.Print "employee[" & i & "] = " & empObj.StringOf("firstName") & " " & empObj.StringOf("lastName")

    i = i + 1
Loop