Visual Basic 6.0

Load Particular CA Certs into a Java KeyStore

See more Java KeyStore (JKS) Examples

Opens a PEM file containing many CA root certificates, and creates a Java keystore containing a subset of the certificates. Visual Basic 6.0

Dim success As Long
success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim jks As New ChilkatJavaKeyStore

Dim troots As New ChilkatTrustedRoots

' Load certificates from a file.
success = troots.LoadCaCertsPem("qa_data/curl_cacert.pem")
If (success <> 1) Then
    Debug.Print troots.LastErrorText
    Exit Sub
End If

Dim sbDn As New ChilkatStringBuilder
Dim sbAlias As New ChilkatStringBuilder
Dim caseSensitive As Long
caseSensitive = 0

Dim i As Long
i = 0
Dim numCerts As Long
numCerts = troots.NumCerts
Dim numAdded As Long
numAdded = 0
Do While (i < numCerts)
    Dim cacert As ChilkatCert
    Set cacert = troots.GetCert(i)
    sbDn.Clear 
    success = sbDn.Append(cacert.SubjectDN)
    If (sbDn.Contains("Entrust.net",caseSensitive) = 1) Then
        Debug.Print cacert.SubjectDN

        ' The alias is an arbitrary unique string for each cert in the JKS.
        sbAlias.Clear 
        success = sbAlias.Append("cacert_")
        success = sbAlias.AppendInt(i + 1)
        success = jks.AddTrustedCert(cacert,sbAlias.GetAsString())
        numAdded = numAdded + 1
    End If

    i = i + 1
Loop

' Verify the number of certs in the JKS equals the number we added.
Dim numJksCerts As Long
numJksCerts = jks.NumTrustedCerts
Debug.Print "NumTrustedCerts = " & numJksCerts
If (numJksCerts <> numAdded) Then
    Debug.Print "Something is amiss!"
    Exit Sub
End If

' Save the JKS.
success = jks.ToFile("myPassword","qa_data/jks/entrust_caCerts.jks")
If (success <> 1) Then
    Debug.Print jks.LastErrorText
    Exit Sub
End If

Debug.Print "Success."

' The output of this program when tested was:

' C=US, O=Entrust.net, OU=www.entrust.net/CPS incorp. by ref. (limits liab.), OU=(c) 1999 Entrust.net Limited, CN=Entrust.net Secure Server Certification Authority
' O=Entrust.net, OU=www.entrust.net/CPS_2048 incorp. by ref. (limits liab.), OU=(c) 1999 Entrust.net Limited, CN=Entrust.net Certification Authority (2048)
' C=US, O="Entrust, Inc.", OU=www.entrust.net/CPS is incorporated by reference, OU="(c) 2006 Entrust, Inc.", CN=Entrust Root Certification Authority
' NumTrustedCerts = 3
' Success.