Visual Basic 6.0

IMAP Read PEC Email of Aruba and Extract the Invoice XML Files

See more Email Object Examples

IMAP Read PEC Email of Aruba and Extract the Invoice XML Files. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New ChilkatImap

' Connect using TLS.
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Authenticate
success = imap.Login("email_account_login","email_account_password")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox/postacert")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Search for messages having "POSTA CERTIFICATA: Invio File" in the subject.
Dim fetchUids As Long
fetchUids = 1
Dim messageSet As New MessageSet
success = imap.QueryMbx("SUBJECT ""POSTA CERTIFICATA: Invio File""",fetchUids,messageSet)
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

If (messageSet.Count < 1) Then
    Debug.Print "No messages found."
    Exit Sub
End If

' For our example, we'll process only the 1st email in the messageSet.
' Download the MIME source of the email into a StringBuilder object.
Dim email As New ChilkatEmail
success = imap.FetchEmail(0,messageSet.GetId(0),messageSet.HasUids,email)
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' The email should contain an attached email.
' The Invoice XML is contained within the attached email.
Dim attachedEmail As New ChilkatEmail
success = email.GetAttachedEmail(0,attachedEmail)
If (success = 0) Then
    Debug.Print email.LastErrorText
    Exit Sub
End If

' Get the MIME of the attached email..
Dim sbMime As New ChilkatStringBuilder
success = attachedEmail.GetMimeSb(sbMime)

' Load it into a Chilkat MIME object.
Dim mime As New ChilkatMime
success = mime.LoadMimeSb(sbMime)

' Examine the structure of the MIME.
Debug.Print mime.GetStructure("text")

' The MIME has this structure:
' multipart/mixed
'     application/octet-stream
'     application/octet-stream     <-- This is where the XML is contained.   It is within an opaque signature.
'     text/plain

' The 2nd application/octet-stream MIME header looks like this:

' ------=_Part_329673_-1348225228.1579889273592
' Content-Type: application/octet-stream; name="SM99999_99aaa.xml.p7m"
' Content-Transfer-Encoding: base64
' Content-Disposition: attachment; filename="SM99999_99aaa.xml.p7m"

' Let's get the binary content of the .p7m
Dim bdP7m As New ChilkatBinData
' Get the 2nd sub-part, at index 1 because index 0 is the 1st sub-part.

Dim mimeP7m As New ChilkatMime
success = mime.PartAt(1,mimeP7m)
If (success = 0) Then
    Debug.Print mime.LastErrorText
    Exit Sub
End If

If (mime.LastMethodSuccess <> 1) Then
    Debug.Print "Failed to get 2nd sub-part. Perhaps the MIME does not have a 2nd sub-part?"
    Exit Sub
End If

success = mimeP7m.GetBodyBd(bdP7m)

' Verify the signature, which also extracts the content contained within the opaque signature.
Dim crypt As New ChilkatCrypt2
success = crypt.OpaqueVerifyBd(bdP7m)
If (success = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' The bdP7m now contains the Invoice XML.
' Load it into an XML object.
Dim xml As New ChilkatXml
success = xml.LoadBd(bdP7m,1)

Debug.Print xml.GetXml()

' We have XML such as the following:
' 
' <?xml version="1.0" encoding="windows-1252"?>
' <?xml-stylesheet type="text/xsl" href="fatturapa_v1.2.xsl"?>
' <p:FatturaElettronica versione="FPR12" xmlns:ds="http://www.w3.org/2000/09/xmldsig#" 
'     xmlns:p="http://ivaservizi.agenziaentrate.gov.it/docs/xsd/fatture/v1.2" 
'     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
'     <FatturaElettronicaHeader>
' 	...
'     </FatturaElettronicaHeader>
'     <FatturaElettronicaBody>
' 	...
'     </FatturaElettronicaBody>
' </p:FatturaElettronica>

' Use this online tool to generate parsing code from sample XML: 
' Generate Parsing Code from XML

Debug.Print "success."