Visual Basic 6.0

IMAP Login Secure

Demonstrates how to use the LoginSecure method introduced in Chilkat v9.5.0.71. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New ChilkatImap

' Connect to an IMAP server..
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.mail.me.com")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Imagine we've previously saved our encrypted login and password within a JSON config file
' that contains this:

' {
'   "imap_login": "fLkxsfnVaIWLiL/R32jo6g==",
'   "imap_password": "/NbaFBoCftBLFf8WBU9Xtw=="
' }

Dim json As New ChilkatJsonObject
success = json.LoadFile("qa_data/passwords/imap.json")

Dim crypt As New ChilkatCrypt2

' These are the encryption settings we previously used to encrypt the credentials within the JSON config file.
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128
crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"
crypt.EncodingMode = "base64"

Dim ssLogin As New ChilkatSecureString
Dim ssPassword As New ChilkatSecureString

' Decrypt to the secure string.  (the strings will still held in memory encrypted, but are now encrypted using
' a randomly generated session key.)
success = crypt.DecryptSecureENC(json.StringOf("imap_login"),ssLogin)
success = crypt.DecryptSecureENC(json.StringOf("imap_password"),ssPassword)

' Pass the credentials to the LoginSecure method:
success = imap.LoginSecure(ssLogin,ssPassword)
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' ...

success = imap.Disconnect()