Visual Basic 6.0

Asynchronous FTP Upload

Demonstrates an asynchronous FTP upload. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ftp As New ChilkatFtp2

ftp.Hostname = "ftp.myftpserver.com"
ftp.Username = "mylogin"
ftp.Password = "mypassword"

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Change to the remote directory where the file will be uploaded.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

Dim localFilepath As String
localFilepath = "qa_data/xml/hamlet.xml"
Dim remoteFilename As String
remoteFilename = "hamlet.xml"

' Call the async version of the PutFile method to return a task object.
' The task object is loaded, but is in the Inert state -- meaning it is
' not yet scheduled to run on Chilkat's background thread pool.
Dim task As ChilkatTask
Set task = ftp.PutFileAsync(localFilepath,remoteFilename)
If (ftp.LastMethodSuccess = 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Before starting the task, tell it to keep an in-memory log of what would've been
' ProgressInfo callbacks.
task.KeepProgressLog = 1

' Schedule the task for running on the thread pool.  This changes the task's state
' from Inert to Live.
success = task.Run()
If (success <> 1) Then
    Debug.Print task.LastErrorText

    Exit Sub
End If

' The application is now free to do anything else
' while the file is being uploaded.

' For this example, we'll simply sleep and periodically
' check to see if the upload is finished, and report the progress
' along the way.
Dim curPctDone As Long
curPctDone = 0
Dim name As String
Dim value As String

Do While task.Finished <> 1

    If (task.PercentDone <> curPctDone) Then
        curPctDone = task.PercentDone
        Debug.Print curPctDone & " percent done"
    End If

    ' Check the progress info log.
    ' Emit any log entries..
    Do While (task.ProgressLogSize > 0)
        ' Get the 1st entry, emit it, and then remove it..
        name = task.ProgressInfoName(0)
        value = task.ProgressInfoValue(0)

        ' Entries reporting the sent byte count will have the name "SendByteCount"
        ' Entries reporting the current bytes-per-second will have the name "SendBytesPerSec"

        Debug.Print name & ": " & value
        task.RemoveProgressInfo 0
    Loop

    ' Sleep 100 ms.
    task.SleepMs 100

Loop

' Just in case there are any remaining entries...
Do While (task.ProgressLogSize > 0)
    ' Get the 1st entry, emit it, and then remove it..
    name = task.ProgressInfoName(0)
    value = task.ProgressInfoValue(0)
    Debug.Print name & ": " & value
    task.RemoveProgressInfo 0
Loop

' A finished task could be one that was canceled, aborted, or truly finished.  

' If the task was "canceled", it was canceled prior to actually starting.  This could
' happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
' background thread pool scheduler.  

' If the task was "aborted", it indicates that it was canceled while running in a background thread.  
' The ResultErrorText will likely indicate that the task was aborted.

' If the task "completed", then it ran to completion, but the actual success/failure of the method
' is determined by the result obtained via a GetResult* method.  (A "completed" task will
' have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
' been aborted or canceled:
If (task.StatusInt <> 7) Then
    Debug.Print "Task did not complete."
    Debug.Print "task status: " & task.Status

    Exit Sub
End If

' The PutFile method returns a boolean.  Therefore, after the task is finished,
' we can get the boolean result by calling GetResultBool.  This is the return value had
' we called PutFile synchronously.
success = task.GetResultBool()
If (success <> 1) Then
    ' The task's ResultErrorText contains what would have been in the LastErrorText property had
    ' the GetFile method been called synchronously.
    Debug.Print task.ResultErrorText
Else
    Debug.Print "File uploaded asynchronously."
End If

success = ftp.Disconnect()