Visual Basic 6.0

Count Files in a Remote FTP Directory

Demonstrates the Chilkat Ftp2.GetDirCount method, which returns the number of files and directories in the current remote directory. It takes no arguments; the first call retrieves the listing, and the count reflects the case-insensitive ListPattern filter. A negative return indicates failure.

Background: GetDirCount is the entry point to Chilkat's index-based directory API: its first call fetches the listing for the current directory into a cache, and the returned count establishes the valid index range (0 through count - 1) for the accessor methods that read names, sizes, and attributes. The ListPattern property narrows the listing to matching names before counting, which is how you list, say, only *.html without filtering in your own code.

Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0

Visual Basic 6.0

Dim success As Long
success = 0

'  Demonstrates the Ftp2.GetDirCount method, which returns the number of files and directories in
'  the current remote directory's listing.  It takes no arguments.  The first call retrieves the
'  listing; the count reflects the case-insensitive ListPattern filter.

Dim ftp As New ChilkatFtp2

ftp.Hostname = "ftp.example.com"
ftp.Username = "myFtpLogin"

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
ftp.Password = "myPassword"

success = ftp.Connect()
If (success = 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

success = ftp.ChangeRemoteDir("public_html")
If (success = 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

'  Optionally filter the listing with a wildcard pattern.  "*" (the default) matches everything.
ftp.ListPattern = "*.html"

Dim n As Long
n = ftp.GetDirCount()
If (n < 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

Debug.Print "Matching entries: " & n

'  The count defines the valid index range 0 through n-1 for the indexed accessor methods.
Dim i As Long
For i = 0 To n - 1
    Dim name As String
    name = ftp.GetFilename(i)
    Debug.Print name
Next

success = ftp.Disconnect()
If (success = 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If