Visual Basic 6.0

Create a DKIM-Signature for a MIME Message

Demonstrates the Chilkat Dkim.DkimSign method, which creates a DKIM-Signature header and prepends it to a complete MIME message held in a BinData, modifying it in place. The DkimAlg, DkimCanon, DkimDomain, DkimSelector, DkimHeaders, and DkimBodyLengthCount properties configure the generated signature.

Note: The file paths are relative to the application's current working directory. Absolute paths may also be used. Supply the paths appropriate to your own environment.

Background: The signature is computed over a hash of the body plus a chosen set of headers, so the message must be completely built — every header, encoding, and boundary — before signing; any later change invalidates it. The d= (domain) and s= (selector) tags tell a verifier where to find the public key: at selector._domainkey.domain in DNS. relaxed/relaxed canonicalization tolerates the minor whitespace changes mail systems make in transit, which is why it is the common choice.

Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0

Visual Basic 6.0

Dim success As Long
success = 0

'  Demonstrates the Dkim.DkimSign method, which creates a DKIM-Signature header and prepends it to
'  a complete MIME message.  The only argument is a BinData holding the MIME, which is modified in
'  place.
'  
'  The DkimAlg, DkimCanon, DkimDomain, DkimSelector, DkimHeaders, and DkimBodyLengthCount
'  properties configure the signature that is generated.

Dim dkim As New ChilkatDkim

'  Configure the DKIM signature.
dkim.DkimDomain = "example.com"
dkim.DkimSelector = "myselector"

'  Signing algorithm written to the a= tag.
dkim.DkimAlg = "rsa-sha256"

'  Canonicalization for headers and body, written to the c= tag.
dkim.DkimCanon = "relaxed/relaxed"

'  Colon-separated list of header fields to sign, written to the h= tag.
dkim.DkimHeaders = "From:To:Subject:Date:Message-ID"

'  Maximum number of canonicalized body bytes to hash.  0 means the entire body.
dkim.DkimBodyLengthCount = 0

'  Load the RSA private key and give it to the Dkim object.
Dim privKey As New PrivateKey
success = privKey.LoadPemFile("qa_data/dkim_private.pem")
If (success = 0) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

success = dkim.SetDkimPrivateKey(privKey)
If (success = 0) Then
    Debug.Print dkim.LastErrorText
    Exit Sub
End If

'  Load the complete MIME message to be signed.  It must already contain all headers, transfer
'  encodings, MIME boundaries, and body bytes.
Dim mimeData As New ChilkatBinData
success = mimeData.LoadFile("qa_data/message.eml")
If (success = 0) Then
    Debug.Print mimeData.LastErrorText
    Exit Sub
End If

'  Sign.  The DKIM-Signature header is prepended to the MIME in place.
success = dkim.DkimSign(mimeData)
If (success = 0) Then
    Debug.Print dkim.LastErrorText
    Exit Sub
End If

'  Save the signed message.
success = mimeData.WriteFile("qa_output/signed.eml")
If (success = 0) Then
    Debug.Print mimeData.LastErrorText
    Exit Sub
End If

Debug.Print "Message signed."