Visual Basic 6.0

Transition from Compression.BeginCompressBytes to FirstChunk/LastChunk

Provides instructions for replacing deprecated BeginCompressBytes method calls with using FirstChunk and LastChunk properties. Visual Basic 6.0

Dim success As Long
success = 0

Dim facSrc As New CkFileAccess
Dim facDest As New CkFileAccess

' Open a large binary file for reading.
success = facSrc.OpenForRead("qa_data/bmp/big.bmp")
If (success = 0) Then
    Debug.Print facSrc.LastErrorText
    Exit Sub
End If

' If we compress in 64K chunks, find out how many blocks there will be.
Dim blockSize As Long
blockSize = 65536
Dim numBlocks As Long
numBlocks = facSrc.GetNumBlocks(blockSize)

' Open an output file for the compressed data.
success = facDest.OpenForWrite("c:/temp/qa_output/compressedBmp.dat")
If (success = 0) Then
    Debug.Print facDest.LastErrorText
    Exit Sub
End If

Dim compress As New ChilkatCompression
compress.Algorithm = "deflate"

Dim fileBytes() As Byte
Dim compressedBytes() As Byte

' ----------------------------------------------------------------------------------
' This is the deprecated way of compressing in chunks using Begin/More/End methods..
' ----------------------------------------------------------------------------------
Dim i As Long
i = 0
Do While i < numBlocks
    fileBytes = facSrc.ReadBlock(i,blockSize)
    If (i = 0) Then
        compressedBytes = compress.BeginCompressBytes(fileBytes)
    Else
        compressedBytes = compress.MoreCompressBytes(fileBytes)
    End If

    success = facDest.FileWrite(compressedBytes)

    i = i + 1
Loop

' At the very end, flush any remaining compressed bytes, if any.
compressedBytes = compress.EndCompressBytes()
success = facDest.FileWrite(compressedBytes)

facSrc.FileClose 
facDest.FileClose 

Debug.Print "Finished compressing file."

' ----------------------------------------------------------------------------------
' This is new way of compressing in chunks using FirstChunk and LastChunk properties
' ----------------------------------------------------------------------------------

success = facSrc.OpenForRead("qa_data/bmp/big.bmp")
If (success = 0) Then
    Debug.Print facSrc.LastErrorText
    Exit Sub
End If

success = facDest.OpenForWrite("c:/temp/qa_output/compressedBmp2.dat")
If (success = 0) Then
    Debug.Print facDest.LastErrorText
    Exit Sub
End If

' Assuming numBlocks > 1
compress.FirstChunk = 1
compress.LastChunk = 0

i = 0
Do While i < numBlocks
    fileBytes = facSrc.ReadBlock(i,blockSize)
    compressedBytes = compress.CompressBytes(fileBytes)

    success = facDest.FileWrite(compressedBytes)

    i = i + 1

    compress.FirstChunk = 0
    If (i = (numBlocks - 1)) Then
        compress.LastChunk = 1
    End If

Loop

facSrc.FileClose 
facDest.FileClose 

Debug.Print "Finished compressing file 2."