Visual Basic 6.0

Create and Verify an Opaque PKCS7/CMS Signature

See more Digital Signatures Examples

Demonstrates how to create a PKCS7 opaque signature, and also how to verify an opaque signature. An opaque signature is different than a detached PKCS7 signature in that it contains the original data. Verifying an opaque signature retrieves the original content. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

' A certificate and private key is needed to create a signature.
' Chilkat provides many different ways to load a certificate and private key, such
' as from a PFX/.p12, Java keystore, JWK, Windows registry-based certificate stores, and other sources.
' This example will load the certificate from a .crt and the private key from a .key file

Dim cert As New ChilkatCert
' The LoadFromFile method will automatically detect the format and load it.
success = cert.LoadFromFile("qa_data/certs/test_12345678a.cer")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Our private key is in an encrypted PKCS8 format.
' If you don't know the format of your key, but you do know it's encrypted,
' and requires a password, then just call any of the Chilkat methods that load
' a private key w/ a password argument.  Chilkat will auto-detect the format
' and load it correctly even if it's not the format indicated by the method name..
Dim privKey As New PrivateKey
Dim password As String
password = "12345678a"
success = privKey.LoadPkcs8EncryptedFile("qa_data/certs/test_12345678a.key",password)
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

' Set properties required for signing.

' Tell it to use the cert and private key we've loaded.
success = crypt.SetSigningCert2(cert,privKey)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Indicate we want the opaque signature in base64 format:
crypt.EncodingMode = "base64"

' Sign the string using the "utf-8" byte representation:
crypt.Charset = "utf-8"

' Create the opaque signature:
Dim originalData As String
originalData = "This is the string to be signed."
Dim opaqueSig As String
opaqueSig = crypt.OpaqueSignStringENC(originalData)
If (crypt.LastMethodSuccess <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print opaqueSig

' The output looks like this:
' MIIPgQYJKoZIhvcNAQcCoIIPcjCCD24CAQExCzAJBgUrDgMCGgUAMC8GCSqGSIb3DQEHAaAiBCBUaGlzIGlzIHRoZSBzdHJpbmcgdG8gYmUgc...

' ----------------------------------------------------------------------------------------------
' Now let's verify the signature and retrieve the original data.
' We'll use a new Crypt2 object to keep things completely separate...

Dim vCrypt As New ChilkatCrypt2

vCrypt.EncodingMode = "base64"
vCrypt.Charset = "utf-8"

Dim extractedData As String
extractedData = vCrypt.OpaqueVerifyStringENC(opaqueSig)
If (vCrypt.LastMethodSuccess <> 1) Then
    Debug.Print vCrypt.LastErrorText
    Exit Sub
End If

Debug.Print "The extracted data: " & extractedData

' The output is:
' The extracted data: This is the string to be signed.