Visual Basic 6.0

Sign String to create a CAdES-T Signature, using HTTP Proxy to Access Timestamp Server

This example will sign a string to create a CAdEST-T signature. It will use an HTTP proxy to access the timestamp server. Visual Basic 6.0

Dim success As Long
success = 0

Dim crypt As New ChilkatCrypt2

Dim cert As New ChilkatCert
cert.SmartCardPin = "123456"
success = cert.LoadFromSmartcard("")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

success = crypt.SetSigningCert(cert)

' Use SHA-256 rather than the default of SHA-1
crypt.HashAlgorithm = "sha256"

' Create JSON that tells Chilkat what signing attributes to include:
Dim attrs As New ChilkatJsonObject
success = attrs.UpdateBool("contentType",1)
success = attrs.UpdateBool("signingTime",1)
success = attrs.UpdateBool("messageDigest",1)
success = attrs.UpdateBool("signingCertificateV2",1)

' A CAdES-T signature is one that includes a timestampToken created by an online TSA (time stamping authority).
' We must include the TSA's URL, as well as a few options to indicate what is desired.
' Except for the TSA URL, the options shown here are typically what you would need.
success = attrs.UpdateBool("timestampToken.enabled",1)
success = attrs.UpdateString("timestampToken.tsaUrl","https://freetsa.org/tsr")
success = attrs.UpdateBool("timestampToken.addNonce",0)
success = attrs.UpdateBool("timestampToken.requestTsaCert",1)
success = attrs.UpdateString("timestampToken.hashAlg","sha256")

crypt.SigningAttributes = attrs.Emit()

Dim strToSign As String
strToSign = "Hello World!"

Dim bd As New ChilkatBinData
success = bd.AppendString(strToSign,"utf-8")

' -------------------------------------------------------------------------
' The purpose of this example is to show how an HTTP object with custom
' settings can be used to access the Internet when signing.
' Access to the Internet is needed to communicate with the timestamp server.
Dim http As New ChilkatHttp
' This can be a domain name, hostname, or IP address.
http.ProxyDomain = "172.16.16.56"
http.ProxyPort = 808
http.ProxyLogin = "myProxyLogin"
http.ProxyPassword = "myProxyPassword"
crypt.SetTsaHttpObj http
' -------------------------------------------------------------------------

' This creates the CAdES-T signature.  During the signature creation, it
' communicates with the TSA to get a timestampToken.
' The contents of bd are signed and replaced with the CAdES-T signature (which embeds the original content).
success = crypt.OpaqueSignBd(bd)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Get the signature in base64 format:
Debug.Print bd.GetEncoded("base64_mime")

Debug.Print "Success."