Visual Basic 6.0 Requires Chilkat v11.7.0+
Visual Basic 6.0
Authenticode Sign a PowerShell Script (.ps1, .psm1, .psd1)
See more Code Signing Examples
Demonstrates how to Authenticode sign a PowerShell script. PowerShell scripts (.ps1), modules (.psm1) and data files (.psd1) can be signed starting in Chilkat v11.7.0. The signature is appended to the file as a comment block, and the file keeps its text encoding.Chilkat Visual Basic 6.0 Downloads
Dim success As Long
success = 0
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
' Signing PowerShell files requires Chilkat v11.7.0 or later.
' The same code signs a script (.ps1), a module (.psm1), or a data file (.psd1).
' Load the code signing certificate. It must have access to its private key.
Dim cert As New ChilkatCert
success = cert.LoadPfxFile("C:/someDir/myCodeSigningCert.pfx","pfx password")
If (success = 0) Then
Debug.Print cert.LastErrorText
Exit Sub
End If
' Sign with SHA256, and ask a timestamp authority for a timestamp. A timestamp lets the
' signature continue to validate after the code signing certificate has expired.
'
' {
' "hashAlg": "sha256",
' "timestampToken": {
' "enabled": true,
' "tsaUrl": "http://timestamp.digicert.com",
' "requestTsaCert": true,
' "hashAlg": "sha256"
' }
' }
Dim json As New ChilkatJsonObject
success = json.UpdateString("hashAlg","sha256")
success = json.UpdateBool("timestampToken.enabled",1)
success = json.UpdateString("timestampToken.tsaUrl","http://timestamp.digicert.com")
success = json.UpdateBool("timestampToken.requestTsaCert",1)
success = json.UpdateString("timestampToken.hashAlg","sha256")
Dim scriptPath As String
scriptPath = "C:/someDir/Deploy.ps1"
Dim signer As New ChilkatCodeSign
' The script is modified in place. The signature is appended to the end of the file as a comment block:
'
' # SIG # Begin signature block
' # MIIoKgYJKoZIhvcNAQcCoIIoGzCCKBcCAQExDzANBglghkgBZQMEAgEFADB5Bgor
' # ...
' # SIG # End signature block
'
' The text encoding of the file (UTF-8, UTF-8 with BOM, or UTF-16) is kept.
' If the script is already signed, the new signature block replaces the existing one.
success = signer.AddSignature(scriptPath,cert,json)
If (success = 0) Then
Debug.Print signer.LastErrorText
Exit Sub
End If
Debug.Print "Signed the PowerShell script."
' Verify the signature that was just added.
' Any change made to the script after it is signed, even to a comment, invalidates the signature.
Dim sigInfo As New ChilkatJsonObject
Dim valid As Long
valid = signer.VerifySignature(scriptPath,sigInfo)
If (valid = 0) Then
Debug.Print signer.LastErrorText
Exit Sub
End If
Debug.Print "The signature is valid."