Visual Basic 6.0

Async Task Chain (another example)

See more Async Examples

Demonstrates using a task chain to run a sequence of FTP tasks asynchronously. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

success = 0

Dim ftp As New ChilkatFtp2

ftp.Hostname = "ftp.example.com"
ftp.Username = "login"
ftp.Password = "password"

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

Dim taskChain As New ChilkatTaskChain

' Create a task to change to the remote directory where the file will be uploaded.
Dim task As ChilkatTask
Set task = ftp.ChangeRemoteDirAsync("junk")
If (ftp.LastMethodSuccess = 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Add this task to the task chain.
success = taskChain.Append(task)

' Create a task to upload a file.
Dim localFilename As String
localFilename = "c:/temp/hamlet.xml"
Dim remoteFilename As String
remoteFilename = "hamlet.xml"

Set task = ftp.PutFileAsync(localFilename,remoteFilename)
If (ftp.LastMethodSuccess = 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Add this task to the task chain.
success = taskChain.Append(task)

' Start the task chain running in a background thread.
' Each task is run one after the other (on the same background thread) until all tasks have completed.
' The task chain will stop at the first task that fails.
taskChain.StopOnFailedTask = 1
success = taskChain.Run()
If (Not success) Then
    Debug.Print taskChain.LastErrorText
    Exit Sub
End If

' The application is now free to do anything else
' while the FTP commands are being run...

' For this example, we'll simply sleep and periodically
' check to see if the taskchain if finished. 
Do While taskChain.Finished <> 1

    ' Sleep 100 ms.
    taskChain.SleepMs 100

Loop

' A finished task chain could be one that was canceled, aborted, or truly finished.  

' If the task chain "completed", then it ran to completion.  A "completed" task will
' have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
' been aborted or canceled:
If (taskChain.StatusInt <> 7) Then
    Debug.Print "Task did not complete."
    Debug.Print "task chain status: " & taskChain.Status
    Exit Sub
End If

' If we got to this point, the ChangeRemoteDir and PutFile were successful.
' We can visually verify by examining the LastErrorText that was recorded for each
' of these method calls..
Dim numTasks As Long
numTasks = taskChain.NumTasks
Dim taskIdx As Long
taskIdx = 0

Do While (taskIdx < numTasks)

    Set task = taskChain.GetTask(taskIdx)

    ' Examine the status of this task, and the ResultErrorText
    ' (the ResultErrorText is the ftp.LastErrorText captured for FTP method called by the task).
    ' Everything should indicate success.
    Debug.Print "task status: " & task.Status
    Debug.Print "task log: " & task.ResultErrorText

    taskIdx = taskIdx + 1
Loop

success = ftp.Disconnect()