Chilkat Examples

ChilkatHOMEAndroid™Classic ASPCC++C#Mono C#.NET Core C#C# UWP/WinRTDataFlexDelphi ActiveXDelphi DLLVisual FoxProJavaLianjaMFCObjective-CPerlPHP ActiveXPHP ExtensionPowerBuilderPowerShellPureBasicCkPythonChilkat2-PythonRubySQL ServerSwift 2Swift 3,4,5...TclUnicode CUnicode C++Visual Basic 6.0VB.NETVB.NET UWP/WinRTVBScriptXojo PluginNode.jsExcelGo

Visual Basic 6.0 Web API Examples

Primary Categories

ABN AMRO
AWS Translate
Activix CRM
Adyen
Amazon MWS
Azure Maps
Azure Monitor
Azure OAuth2
Azure Storage Accounts
Bluzone
CardConnect
ClickBank
Clickatell
Cloudfare
DocuSign
ETrade
Etsy
Facebook
GeoOp
GetHarvest
Global Payments
Google Search Console
Hungary NAV Invoicing
Jira
MYOB
Magento
MercadoLibre

Microsoft Calendar
Microsoft Group
Microsoft Tasks and Plans
Okta OAuth/OIDC
OneLogin OIDC
PayPal
Peoplevox
Populi
QuickBooks
Rabobank
SOAP finkok.com
Shippo
Shopify
Stripe
SugarCRM
Trello
Twilio
Twitter
VoiceBase
Vonage
Walmart
Walmart v3
WhatsApp
WooCommerce
Xero
Yousign
_Miscellaneous_
eBay
effectconnect

 

 

 

(Visual Basic 6.0) Adyen HMAC Signature Calculation for Hosted Payment Pages

Demonstrates how to do the HMAC Signature Calculation for a hosted payment page (HPP) in Adyen.

For a C# ASP.NET Razor Pages example showing the HTML Form with HMAC signature code, see Adyen HMAC Signature Calculation in C#

For more information, see https://docs.adyen.com/classic-integration/hosted-payment-pages/hmac-signature-calculation/

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long

Dim strHtml As String
strHtml = "<table class=""od""><tr><th>Description</th><th>Quantity</th><th>Amount</th></tr><tr><td>1 Digital Camera</td><td class=""r"">1</td><td class=""r"">100 GBP</td></tr><tr><td class=""b"">Total</td><td class=""r""></td><td class=""b r"">100.00 GBP</td></tr></table>"

Dim gzip As New ChilkatGzip
Dim gzOrderData As String
gzOrderData = gzip.CompressStringENC(strHtml,"utf-8","base64")

Dim xml As New ChilkatXml
xml.Tag = "keyValuePairs"

xml.NewChild2 "orderData",gzOrderData

' required, The payment deadline; the payment needs to occur within the specified time value.
Dim sessionValidity As String
sessionValidity = "2019-08-11T10:30:00Z"
xml.NewChild2 "sessionValidity",sessionValidity

' optional.  Normally we'll let Adyen automatically know the country based on the IP address.
' By default, the payment methods offered to a shopper are filtered based on the country the shopper's IP address is mapped to. 
' In this way, shoppers are not offered payment methods that are not available in the country they are carrying out the transaction from. 
' This IP-to-country mapping is not 100% accurate, so if you have already established the country of the shopper, you can set it explicitly 
' in the countryCode parameter.
Dim countryCode As String
countryCode = "GB"
xml.NewChild2 "countryCode",countryCode

' optional
Dim shopperLocale As String
shopperLocale = "en_GB"
' If not specified, the locale preference is set to en_GB   by default.
' When it is not necessary to include the country-specific part, use only the language code.
' For example: it instead of it_IT to set the locale preferences to Italian.
xml.NewChild2 "shopperLocale",shopperLocale

' required, A reference to uniquely identify the payment. This reference is used in all communication with you about the payment status. 
' We recommend using a unique value per payment; however, it is not a requirement. If you need to provide multiple references for a transaction, 
' you can enter them in this field. Separate each reference value with a hyphen character ("-"). This field has a length restriction: 
' you can enter max. 80 characters.
Dim merchantReference As String
merchantReference = "paymentTest1234"
xml.NewChild2 "merchantReference",merchantReference

' required, The merchant account identifier you want to process the (transaction) request with.
Dim merchantAccount As String
merchantAccount = "ChilkatSoftwareIncCOM"
xml.NewChild2 "merchantAccount",merchantAccount

' required.  10000 for $100.00
Dim paymentAmount As String
paymentAmount = "10000"
xml.NewChild2 "paymentAmount",paymentAmount

' required, The three-character ISO currency code
Dim currencyCode As String
currencyCode = "GBP"
xml.NewChild2 "currencyCode",currencyCode

' required.
Dim skinCode As String
skinCode = "S7uWsvfB"
xml.NewChild2 "skinCode",skinCode

' optional, A unique identifier for the shopper, for example, a customer ID.
' We recommend providing this information, as it is used in velocity fraud checks. It is also the key in recurring payments.
' This field is mandatory in recurring payments.  
Dim shopperReference As String
shopperReference = "somebody@example.com"
xml.NewChild2 "shopperReference",shopperReference

' optional
Dim shopperEmail As String
shopperEmail = "somebody@example.com"
xml.NewChild2 "shopperEmail",shopperEmail

' optional, An integer value that adds up to the normal fraud score.
' The value can be either a positive or negative integer.
xml.NewChild2 "offset","0"

' Apparently this is a required field.
Dim shipBeforeDate As String
shipBeforeDate = "2019-06-04"
xml.NewChild2 "shipBeforeDate",shipBeforeDate

xml.SortByTag 1

' Encode...
'  "\" (backslash) as "\\"
'  ":" (colon) as "\:"

Dim sbTags As New ChilkatStringBuilder
Dim sbValues As New ChilkatStringBuilder

Dim sbContent As New ChilkatStringBuilder
Dim n As Long
n = xml.NumChildren
Dim i As Long
i = 0
Do While i < n
    If (i > 0) Then
        success = sbTags.Append(":")
        success = sbValues.Append(":")
    End If

    success = xml.GetChild2(i)
    success = sbTags.Append(xml.Tag)

    success = sbContent.SetString(xml.Content)
    Dim numReplaced As Long
    numReplaced = sbContent.Replace("\","\\")
    numReplaced = sbContent.Replace(":","\:")
    success = sbValues.AppendSb(sbContent)
    success = xml.GetParent2()

    i = i + 1
Loop

Dim sbSigningStr As New ChilkatStringBuilder
success = sbSigningStr.AppendSb(sbTags)
success = sbSigningStr.Append(":")
success = sbSigningStr.AppendSb(sbValues)

Dim crypt As New ChilkatCrypt2
crypt.HashAlgorithm = "sha256"
crypt.MacAlgorithm = "hmac"

Dim hmacKey As String
hmacKey = "934D1E806DDD99595EB430076FD7F8E4D12D0A3F51243A4C0C3897703118E739"
success = crypt.SetMacKeyEncoded(hmacKey,"hex")

crypt.EncodingMode = "base64"
Dim merchantSig As String
merchantSig = crypt.HmacStringENC(sbSigningStr.GetAsString())

Debug.Print merchantSig

 

© 2000-2020 Chilkat Software, Inc. All Rights Reserved.