(Excel) SendRawEmail (HTML Email with PDF Attachment)

IMPORTANT: This example requires Chilkat v9.5.0.61 or greater. If this version is not yet available, send email to support@chilktasoft.com. Chilkat will provide the new version upon request.

Demonstrates how to use the SES SendRawEmail action to send an email with an attachment. Note: The total size of an SES email cannot exceed 10MB.

See SES SendRawEmail for more information.

Download Excel Class Modules

Chilkat Excel Class Modules

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Let's first prepare the email to be sent..
Dim email As Chilkat.Email
Set email = Chilkat.NewEmail
email.Subject = "Test email with PDF attachment."
email.SetHtmlBody "<html><body><p>This is a test <b>HTML email with a PDF attachment</b></p></body></html>"

' The AddFileAttachment method returns the content-type selected based on the 
' file extension.   This example has no need of using the return value..

contentType = email.AddFileAttachment("qa_data/pdf/fishing.pdf")
If (email.LastMethodSuccess <> True) Then
    Debug.Print email.LastErrorText
    Exit Sub
End If

' Add the From header, and some recipients.
' The From address should be an email address verified for use
' as a sender for your Amazon SES account.
' The From address will also be the Source parameter for the SES SendRawEmail request.
email.From = "Chilkat Software <admin@chilkatdownload.com>"

' Add recipients...
' Note: We DO NOT add BCC recipients to the email.  A BCC address should not be
' present in the MIME header of the email (otherwise it would not be "blind" because
' other recipients would be able to see it).
' These same addresses will be added as parameters to the SendRawEmail request.
' (BCC addresses are added as parameters at that time.)
Dim success As Boolean
success = email.AddTo("Mr. Simulator","success@simulator.amazonses.com")
success = email.AddCC("Chilkat Support","support@chilkatsoft.com")
success = email.AddCC("Some Yahoo","somebody@yahoo.com")

' Get the MIME of the email to be sent.

mimeStr = email.GetMime()

' We'll need the MIME base64 encoded for the SES REST request..
Dim crypt As Chilkat.Crypt2
Set crypt = Chilkat.NewCrypt2

mimeBase64 = crypt.EncodeString(mimeStr,"utf-8","base64")

' OK.. our MIME email is prepared.  Now use Chilkat REST to send it..

Dim rest As Chilkat.Rest
Set rest = Chilkat.NewRest

' Connect to the Amazon AWS REST server.
' such as https://email.us-west-2.amazonaws.com/

bTls = True

port = 443

bAutoReconnect = True

success = rest.Connect("email.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
Dim authAws As Chilkat.AuthAws
Set authAws = Chilkat.NewAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
' the region should match our URL above..
authAws.Region = "us-west-2"
authAws.ServiceName = "ses"

success = rest.SetAuthAws(authAws)

success = rest.AddQueryParam("Action","SendRawEmail")

success = rest.AddQueryParam("RawMessage.Data",mimeBase64)

' Add up to 100 TO, CC, and BCC recipients.
' If your SES account is still in the sandbox, you also must verify every recipient email address except for the recipients 
' provided by the Amazon SES mailbox simulator. (See http://docs.aws.amazon.com/ses/latest/DeveloperGuide/mailbox-simulator.html)
success = rest.AddQueryParam("Destination.ToAddresses.member.1","success@simulator.amazonses.com")
' Please do not test by sending email to Chilkat (Thank You!)
' Please do not test by sending email to Chilkat (Thank You!)
' Please do not test by sending email to Chilkat (Thank You!)
success = rest.AddQueryParam("Destination.CcAddresses.member.1","support@chilkatsoft.com")
success = rest.AddQueryParam("Destination.CcAddresses.member.2","somebody@yahoo.com")
success = rest.AddQueryParam("Destination.BccAddresses.member.1","somebody@gmail.com")

success = rest.AddQueryParam("Source","admin@chilkatdownload.com")

' Because there may be a large amount of data in the query params, use a POST
' where the params are sent in the body of the HTTP Request.

responseXml = rest.FullRequestFormUrlEncoded("POST","/")
If (rest.LastMethodSuccess <> True) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "response status code = "; rest.ResponseStatusCode
    Debug.Print "response status text = "; rest.ResponseStatusText
    Debug.Print "response header: "; rest.ResponseHeader
    Debug.Print "response body: "; responseXml
    Exit Sub
End If

' Examine the successful XML response.
Dim xml As Chilkat.Xml
Set xml = Chilkat.NewXml
success = xml.LoadXml(responseXml)
Debug.Print xml.GetXml()

' To get the MessageId
Debug.Print "MessageId: "; xml.ChilkatPath("SendEmailResult|MessageId|*")

' A sample successful response:
' <?xml version="1.0" encoding="utf-8" ?>
' <SendEmailResponse xmlns="http://ses.amazonaws.com/doc/2010-12-01/">
'     <SendEmailResult>
'         <MessageId>010101579081d2c1-043c693f-5a23-4c64-a8c1-66187d3725a0-000000</MessageId>
'     </SendEmailResult>
'     <ResponseMetadata>
'         <RequestId>e2b5b480-8a4e-11e6-85cd-21b1f1f6d432</RequestId>
'     </ResponseMetadata>
' </SendEmailResponse>