B4X Requires Chilkat v11.0.0+
B4X
Uni Economy API Client Credentials Flow
See more OAuth2 Examples
Demonstrates how to do OAuth 2.0 using the client credentials flow for the Uni Economy API. (This means that the server can authenticate against the identity server without human interaction.)Chilkat B4X Downloads
Dim success As Boolean = False
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
' Step 1 ------------------------------------------------------------------------------------------
' First create a client token...
Dim cert As ChilkatCert
cert.Initialize("cert")
cert.VerboseLogging = True
' Note: .pfx and .p12 files are identical. The only difference is the file extension.
' Also, if your .p12 password is longer than 64 chars, you'll need Chilkat v9.5.0.83 or later.
' To shorten the password, import your .p12 onto your Windows computer by double-clicking on the .p12 file,
' make sure when importing that keys are exportable, then re-export with private keys to a .pfx with a new password.
success = cert.LoadPfxFile("qa_data/pfx/UniCert_Norge_Test_secret.pfx", "secret")
If success = False Then
Log(cert.LastErrorText)
Return
End If
Dim privKey As ChilkatPrivateKey
privKey.Initialize("privKey")
success = cert.GetPrivateKey(privKey)
If success = False Then
Log(cert.LastErrorText)
Return
End If
Dim jwt As ChilkatJwt
jwt.Initialize
' Build the JOSE header
Dim jose As ChilkatJsonObject
jose.Initialize
' Use RS256. Pass the string "RS384" or "RS512" to use RSA with SHA-384 or SHA-512.
success = jose.AppendString("alg", "RS256")
success = jose.AppendString("typ", "JWT")
' Now build the JWT claims (also known as the payload)
' Our JWT claims will contain members as shown here:
' {
' "jti": "ad612fce-3e71-4f6a-8af1-7eb0414b4eea", <-- generated unique global identifier
' "sub": "99999999-aaaa-bbbb-cccc-ddddeeeeffff", <-- This is the clientId
' "iat": 1588102982, <-- These are date/time values.
' "nbf": 1588102982,
' "exp": 1588103042,
' "iss": " 99999999-aaaa-bbbb-cccc-ddddeeeeffff",
' "aud": "https://test-login.unieconomy.no/connect/token"
' }
' Use your own client ID.
Dim myClientId As String = "99999999-aaaa-bbbb-cccc-ddddeeeeffff"
Dim claims As ChilkatJsonObject
claims.Initialize
Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")
claims.AppendString("jti", crypt.GenerateUuid)
claims.AppendString("sub", myClientId)
' Set the timestamp of when the JWT was created to now minus 60 seconds
Dim curDateTime As Int = jwt.GenNumericDate(-60)
success = claims.AddIntAt(-1, "iat", curDateTime)
' Set the "not process before" timestamp to now minus 60 seconds
success = claims.AddIntAt(-1, "nbf", curDateTime)
' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1, "exp", curDateTime + 3600)
claims.AppendString("iss", myClientId)
claims.AppendString("aud", "https://test-login.unieconomy.no/connect/token")
' Produce the smallest possible JWT:
jwt.AutoCompact = True
' Create the JWT token. This is where the RSA signature is created.
Dim jwt_token As String = jwt.CreateJwtPk(jose.Emit, claims.Emit, privKey)
Log(jwt_token)
' Step 2 ------------------------------------------------------------------------------------------
Dim http As ChilkatHttp
http.Initialize("http")
' Fetch the discovery document...
Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpNoBody("GET", "https://test-login.unieconomy.no/.well-known/openid-configuration", resp)
If success = False Then
Log(http.LastErrorText)
Return
End If
If resp.StatusCode <> 200 Then
Log("Received response status code " & resp.StatusCode)
Log("Response body containing error text or JSON:")
Log(resp.BodyStr)
Return
End If
Dim json As ChilkatJsonObject
json.Initialize
success = json.Load(resp.BodyStr)
json.EmitCompact = False
Log(json.Emit)
' We have the discovery document, which contains something like this:
' You can use this online tool to generate parsing code from sample JSON:
' Generate Parsing Code from JSON
' {
' "issuer": "https://test-login.unieconomy.no",
' "jwks_uri": "https://test-login.unieconomy.no/.well-known/openid-configuration/jwks",
' "authorization_endpoint": "https://test-login.unieconomy.no/connect/authorize",
' "token_endpoint": "https://test-login.unieconomy.no/connect/token",
' "userinfo_endpoint": "https://test-login.unieconomy.no/connect/userinfo",
' "end_session_endpoint": "https://test-login.unieconomy.no/connect/endsession",
' "check_session_iframe": "https://test-login.unieconomy.no/connect/checksession",
' "revocation_endpoint": "https://test-login.unieconomy.no/connect/revocation",
' "introspection_endpoint": "https://test-login.unieconomy.no/connect/introspect",
' "device_authorization_endpoint": "https://test-login.unieconomy.no/connect/deviceauthorization",
' "frontchannel_logout_supported": true,
' "frontchannel_logout_session_supported": true,
' "backchannel_logout_supported": true,
' "backchannel_logout_session_supported": true,
' "scopes_supported": [
' "openid",
' "profile",
' "email",
' "offline_access",
' "AppFramework.All",
' "AppFramework",
' "AppFramework.Sales",
' "IdentityAPI",
' "widgetApi",
' "TestScope.test",
' "TestScope.Cars",
' "HaglandAPI",
' "LicenseAdmin",
' "LicenseAdmin.Product.Read",
' "SoftRig.Product.Write",
' "TestAPI.test",
' "offline_access"
' ],
' "claims_supported": [
' "sub",
' "updated_at",
' "name",
' "family_name",
' "given_name",
' "middle_name",
' "nickname",
' "preferred_username",
' "picture",
' "website",
' "gender",
' "birthdate",
' "zoneinfo",
' "locale",
' "profile",
' "email",
' "email_verified"
' ],
' "grant_types_supported": [
' "authorization_code",
' "client_credentials",
' "refresh_token",
' "implicit",
' "password",
' "urn:ietf:params:oauth:grant-type:device_code",
' "delegation"
' ],
' "response_types_supported": [
' "code",
' "token",
' "id_token",
' "id_token token",
' "code id_token",
' "code token",
' "code id_token token"
' ],
' "response_modes_supported": [
' "form_post",
' "query",
' "fragment"
' ],
' "token_endpoint_auth_methods_supported": [
' "client_secret_basic",
' "client_secret_post",
' "private_key_jwt",
' "private_key_jwt"
' ],
' "id_token_signing_alg_values_supported": [
' "RS256"
' ],
' "subject_types_supported": [
' "public"
' ],
' "code_challenge_methods_supported": [
' "plain",
' "S256"
' ],
' "request_parameter_supported": true
' }
' ------------------------------------------------------
' The next steps are to (1) get the token_endpoint,
' and (2) verify that the client_credentials grant type is supported.
Dim tokenEndpoint As String = json.StringOf("token_endpoint")
Dim grantTypes As ChilkatJsonArray = json.ArrayOf("grant_types_supported")
Dim clientCredentialsIdx As Int = grantTypes.FindString("client_credentials", True)
' If clientCredentialsIdx is less then zero (-1) then the "client_credentials" string was not found.
If clientCredentialsIdx < 0 Then
Log("The client credentials grant type is not supported.")
Return
End If
' ------------------------------------------------------
' Request the access token using our Client ID and JWT
Dim req As ChilkatHttpRequest
req.Initialize
req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"
req.AddParam("client_id", myClientId)
req.AddParam("scope", "AppFramework.Sales")
req.AddParam("grant_type", "client_credentials")
req.AddParam("client_assertion_type", "urn:ietf:params:oauth:client-assertion-type:jwt-bearer")
req.AddParam("client_assertion", jwt_token)
success = http.HttpReq(tokenEndpoint, req, resp)
If success = False Then
Log(http.LastErrorText)
Return
End If
' Make sure we got a 200 response status code, otherwise it's an error.
If resp.StatusCode <> 200 Then
Log("POST to token endpoint failed.")
Log("Received response status code " & resp.StatusCode)
Log("Response body containing error text or JSON:")
Log(resp.BodyStr)
Return
End If
success = json.Load(resp.BodyStr)
Log(json.Emit)
' The JSON response will look like this:
' {
' "access_token": "...",
' "expires_in": 3600,
' "token_type": "Bearer",
' "scope": "AppFramework.Sales"
' }
' Get the access token:
Dim accessToken As String = json.StringOf("access_token")
Log("accessToken = " & accessToken)
' ------------------------------------------------------
' Use the access token in a request.
' We'll just send a GET request to https://test.unieconomy.no/api/init/companies
' Tell the http object to use the OAuth2 access token in the "Authorization: Bearer ..." header.
http.AuthToken = accessToken
Dim sbResponse As ChilkatStringBuilder
sbResponse.Initialize
success = http.QuickGetSb("https://test.unieconomy.no/api/init/companies", sbResponse)
If success = False Then
Log(http.LastErrorText)
Return
End If
' Examine the response status code.
If http.LastStatus <> 200 Then
Log(sbResponse.GetAsString)
Log("response status: " & http.LastStatus)
Log("Received error response.")
Return
End If
json.LoadSb(sbResponse)
Log(json.Emit)
Log("Success.")