B4X

Get the Exit Status of a Remote SSH Command

Demonstrates the Chilkat Ssh.GetChannelExitStatus method, which returns the remote process exit status for a channel. The only argument is the channel number. Call it only after ChannelReceivedExitStatus returns true.

Background: The exit status is how you learn whether a remote command actually succeeded — recall that a successful exec request only means the request was accepted. By Unix convention 0 means success and any nonzero value indicates a failure. Retrieve it promptly after the receive operation and before calling unrelated SSH methods or releasing the channel, since the completed channel record can be discarded.

Chilkat B4X Downloads

Download Chilkat for B4X

B4X

Dim success As Boolean = False

'  Demonstrates the Ssh.GetChannelExitStatus method, which returns the remote process exit
'  status for a channel.  The only argument is the channel number.  Call it only after
'  ChannelReceivedExitStatus returns True.

Dim ssh As ChilkatSsh
ssh.Initialize("ssh")

Dim sshPort As Int = 22
success = ssh.Connect("ssh.example.com", sshPort)
If success = False Then
    Log(ssh.LastErrorText)
    Return
End If


'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
Dim password As String = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin", password)
If success = False Then
    Log(ssh.LastErrorText)
    Return
End If


Dim channelNum As Int = ssh.OpenSessionChannel
If channelNum < 0 Then
    Log(ssh.LastErrorText)
    Return
End If


success = ssh.SendReqExec(channelNum, "grep -q root /etc/passwd")
If success = False Then
    Log(ssh.LastErrorText)
    Return
End If


'  IMPORTANT: Set a read timeout.  ReadTimeoutMs defaults to 0, which means no limit -- without
'  it, this call waits forever if the server never sends channel close.
ssh.ReadTimeoutMs = 15000

success = ssh.ChannelReceiveToClose(channelNum)
If success = False Then
    Log(ssh.LastErrorText)
    Return
End If


'  Retrieve the exit status immediately, before calling unrelated SSH methods or releasing the
'  channel, because the completed channel record can be discarded.
If ssh.ChannelReceivedExitStatus(channelNum) Then
    Dim exitStatus As Int = ssh.GetChannelExitStatus(channelNum)
    Log("Exit status: " & exitStatus)

    '  By convention, 0 means the remote command succeeded.
    If exitStatus = 0 Then
        Log("The remote command succeeded.")
    Else
        Log("The remote command reported a failure.")
    End If

End If


ssh.Disconnect