B4X

Socket Send/Receive 16-bit Integers

Demonstrates sending and receiving 16-bit integers over a socket connection using either big-endian or little-endian byte ordering. B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim sock As ChilkatSocket
sock.Initialize("sock")

'  --------------------------------------------------------------------
'  This example uses the public TCP echo service at https://tcpbin.com/
'  --------------------------------------------------------------------

Dim useTls As Boolean = False
Dim port As Int = 4242
Dim maxWaitMs As Int = 5000
success = sock.Connect("tcpbin.com", port, useTls, maxWaitMs)
If success = False Then
    Log(sock.LastErrorText)
    Return
End If


'  Wait a max of 2 seconds for a response..
sock.MaxReadIdleMs = 2000

'  Send a 16-bit integer using big-endian byte ordering (also called network byte order)
'  12022 decimal = 2EF6 hex
Dim value As Int = 12022
Dim bigEndian As Boolean = True
sock.SendInt16(value, bigEndian)
'  Send it again, because we'll read it two different ways..
sock.SendInt16(value, bigEndian)

'  The tcpbin.com echo server only echoes after receiving an LF (linefeed char)
sock.SendByte(10)

'  Let's see hex values of the 2 bytes sent in network byte order (big-endian)
'  (The echo server sends back exactly the bytes received.)
Dim hexStr As String = sock.ReceiveNBytesENC(2, "hex")

'  In the big-ending byte order, the byte order is most significant byte to least significant,
'  therefore we should see the bytes in the order 0x2E 0xF6.
Log("Expecting big-endian 2EF6")
Log(hexStr)

'  Let's read directly to an integer..
success = sock.ReceiveInt16(bigEndian, True)
Log("Expecting 12022")
Log("Received: " & sock.ReceivedInt)

'  Consume the LF that gets echoed back..
sock.ReceiveByte(True)

'  --------------------------------------------------------------------
'  Let's do the same thing, but with little-endian byte ordering.

Log("----")

'  12022 decimal = 2EF6 hex, but little-endian byte ordering will send the bytes in the order 0xF6 0x2E
value = 12022
bigEndian = False
sock.SendInt16(value, bigEndian)
sock.SendInt16(value, bigEndian)
sock.SendByte(10)

hexStr = sock.ReceiveNBytesENC(2, "hex")

Log("Expecting little-endian F62E")
Log(hexStr)

success = sock.ReceiveInt16(bigEndian, True)
Log("Expecting 12022")
Log("Received: " & sock.ReceivedInt)

'  Consume the LF that gets echoed back..
sock.ReceiveByte(True)

sock.Close(1000)

'  Output:

'  Expecting big-endian 2EF6
'  2EF6
'  Expecting 12022
'  Received: 12022
'  ----
'  Expecting little-endian F62E
'  F62E
'  Expecting 12022
'  Received: 12022