B4X

OAuth2 for a GMail using a P12 Service Account Key

See more GMail REST API Examples

Demonstrates how to use GMail with OAuth2 for a service account within a Google Workspace Account where your email domain is custom (e.g., @yourcompany.com).

Note: This example does not work for Personal Google Accounts where the email domain is @gmail.com

B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim http As ChilkatHttp
http.Initialize("http")

'  --------------------------------------------------------------------------------
'  For a step-by-step guide for setting up your Google Workspace service account,
'  see Setup Google Workspace Account for Sending SMTP GMail from a Service Account
'  --------------------------------------------------------------------------------
'  Begin by loading your Google service account key (.p12)
Dim cert As ChilkatCert
cert.Initialize("cert")
success = cert.LoadPfxFile("c:/someDirectory/keys/chilkat25-cbd7b42afbd8.p12", "notasecret")
If success <> True Then
    Log(cert.LastErrorText)
    Return
End If


'  The ISS is your service account email address ending in gserviceaccount.com.
Dim iss As String = "chilkatsvc@chilkat25.iam.gserviceaccount.com"

'  The scope is always the following string:
Dim scope As String = "https://mail.google.com/"

'  The sub is your company email address
Dim oauth_sub As String = "bob@yourcompany.com"

'  The access token is valid for this number of seconds.
Dim numSec As Int = 3600

Dim accessToken As String = http.G_SvcOauthAccessToken(iss, scope, oauth_sub, numSec, cert)
If http.LastMethodSuccess <> True Then
    Log(http.LastErrorText)
    Return
Else
    Log("access token: " & accessToken)
End If


'  The access token allows us to send unlimited emails while it's valid. Once it expires, we must obtain and use a new one.

'  -----------------------------------------------------------------------
Dim mailman As ChilkatMailMan
mailman.Initialize("mailman")

'  Set the properties for the GMail SMTP server:
mailman.SmtpHost = "smtp.gmail.com"
mailman.SmtpPort = 587
mailman.StartTLS = True

mailman.SmtpUsername = "bob@yourcompany.com"
mailman.OAuth2AccessToken = accessToken

'  Create a new email object
Dim email As ChilkatEmail
email.Initialize

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Bob <bob@yourcompany.com>"
success = email.AddTo("Recipient", "recipient@example.com")
'  To add more recipients, call AddTo, AddCC, or AddBcc once per recipient.

success = mailman.SendEmail(email)
If success <> True Then
    Log(mailman.LastErrorText)
    Return
End If


success = mailman.CloseSmtpConnection
If success <> True Then
    Log("Connection to SMTP server not closed cleanly.")
End If


Log("Successfully sent email using Gmail with a service account key.")