B4X

Sign XML to Create P7S

See more CAdES Examples

Demonstrates how to sign XML to create a P7S. B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")

Dim cert As ChilkatCert
cert.Initialize("cert")
success = cert.LoadPfxFile("qa_data/pfx/cert_test123.pfx", "test123")
If success <> True Then
    Log(cert.LastErrorText)
    Return
End If


'  Tell the crypt component to use this cert.
success = crypt.SetSigningCert(cert)
If success <> True Then
    Log(crypt.LastErrorText)
    Return
End If


'  The CadesEnabled property applies to all methods that create PKCS7 signatures. 
'  To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = True

crypt.HashAlgorithm = "sha256"

'  We can sign any type of file, creating a .p7s as output.
'  The .p7s contains the signature and also embeds the data of the file that is signed.
Dim inFile As String = "qa_data/xml/sample1.xml"
Dim p7sFile As String = "qa_output/sample1.xml.p7s"

'  Create the CAdES-BES attached signature, which contains the original data.
'  Note: Chilkat's function naming is not accurate.  CreateP7M creates a PKCS7 signature where the signed file
'  is contained within the signature.  CreateP7S creates a detached PKCS7 signature where the signed file
'  is NOT contained within the signature.  We want the data to be contained in the signature, therefore
'  we call CreateP7M even though we are naming our output file .p7s.
success = crypt.CreateP7M(inFile, p7sFile)
If success = False Then
    Log(crypt.LastErrorText)
    Return
End If


'  Verify the .p7s file and extract the original file from the .p7s. 
Dim extractedToFilePath As String = "qa_output/sample1.xml"
success = crypt.VerifyP7M(p7sFile, extractedToFilePath)
If success = False Then
    Log(crypt.LastErrorText)
    Return
End If


Log("Success!")