B4X Requires Chilkat v11.0.0+

SFTP Auth Failure Reason (AuthenticatePwPk)

See more SFTP Examples

This example demonstrates how to determine the failure reason for the case where both a password and private key are required for authentication. If authentication fails, was it because of an invalid private key, or an invalid password? B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  Load a private key to be used for SSH authentication.
Dim key As ChilkatSshKey
key.Initialize
key.Password = "key_password"

success = key.FromOpenSshPrivateKey(key.LoadText("qa_data/my_private_key_file"))
If success = False Then
    Log(key.LastErrorText)
    Return
End If


Dim sftp As ChilkatSFtp
sftp.Initialize("sftp")

success = sftp.Connect("sftp.example.com", 22)
If success = False Then
    Log(sftp.LastErrorText)
    Return
End If


'  Authenticate using both a password and private key.
success = sftp.AuthenticatePwPk("myLogin", "myPassword", key)
If success = True Then
    Log("Authentication is successful!")
    Return
End If


'  If we get here, it means the authentication failed.
'  Examine the last JSON data..

Dim json As ChilkatJsonObject
json.Initialize
sftp.GetLastJsonData(json)

json.EmitCompact = False

'  This is the JSON if the key is correct, but the password is incorrect:

'  {
'    "public_key_type": "rsa",
'    "partialAuthResult": "publickey success. continue to authenticate with password...",
'    "authResult": "failed",
'    "authFailReason": "Password is incorrect"
'  }

'  This is the JSON if the key is incorrect.  We won't know if the password is also incorrect until
'  the key is made correct so that authentication proceeds to check the password.

'  {
'    "public_key_type": "rsa",
'    "authResult": "failed",
'    "authFailReason": "Key is incorrect"
'  }

'  To get the authResult anbd authFailReason:
Log("authResult: " & json.StringOf("authResult"))
Log("authFailReason: " & json.StringOf("authFailReason"))