B4X Requires Chilkat v11.0.0+
B4X
QuickBooks - Query Employees
See more QuickBooks Examples
Demonstrates how to query the QuickBooks employee data.Chilkat B4X Downloads
Dim success As Boolean = False
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
' Get our previously obtained OAuth2 access token, which should contain JSON like this:
' {
' "expires_in": 3600,
' "x_refresh_token_expires_in": 8726400,
' "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
' "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
' "token_type": "bearer"
' }
Dim jsonToken As ChilkatJsonObject
jsonToken.Initialize
success = jsonToken.LoadFile("qa_data/tokens/qb-access-token.json")
Dim rest As ChilkatRest
rest.Initialize("rest")
' Connect using TLS.
' A single REST object, once connected, can be used for many Quickbooks REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim bAutoReconnect As Boolean = True
success = rest.Connect("sandbox-quickbooks.api.intuit.com", 443, True, bAutoReconnect)
If success = False Then
Log(rest.LastErrorText)
Return
End If
Dim sbAuth As ChilkatStringBuilder
sbAuth.Initialize
sbAuth.Append("Bearer ")
sbAuth.Append(jsonToken.StringOf("access_token"))
rest.Authorization = sbAuth.GetAsString
rest.AddHeader("Accept", "application/json")
rest.AllowHeaderFolding = False
Dim query As String = "select * from Employee"
rest.AddQueryParam("query", query)
rest.AddQueryParam("minorversion", "45")
' The company ID is 123146096291789
Dim responseBody As String = rest.FullRequestNoBody("GET", "/v3/company/123146096291789/query")
If rest.LastMethodSuccess = False Then
Log(rest.LastErrorText)
Return
End If
' We should expect a 200 response if successful.
If rest.ResponseStatusCode <> 200 Then
Log("Request Header: ")
Log(rest.LastRequestHeader)
Log("----")
Log("Response StatusCode = " & rest.ResponseStatusCode)
Log("Response StatusLine: " & rest.ResponseStatusText)
Log("Response Header:")
Log(rest.ResponseHeader)
Log(responseBody)
Return
End If
' Load the JSON response into a JSON object for parsing.
' A sample JSON response is shown below.
Dim json As ChilkatJsonObject
json.Initialize
json.Load(responseBody)
' Show the full JSON response.
json.EmitCompact = False
Log(json.Emit)
' Use this online tool to generate parsing code from sample JSON:
' Generate Parsing Code from JSON
' These will be used for parsing date/time strings..
Dim dtime As ChilkatDateTime
dtime.Initialize
Dim bLocalTime As Boolean = True
Dim dt As ChilkatDtObj
dt.Initialize
' Iterate over each account returned.
Dim numRecords As Int = json.SizeOfArray("QueryResponse.Employee")
Dim i As Int = 0
Do While i < numRecords
json.I = i
Log("DisplayName: " & json.StringOf("QueryResponse.Employee[i].DisplayName"))
Log("Id: " & json.StringOf("QueryResponse.Employee[i].Id"))
Log("Active: " & json.BoolOf("QueryResponse.Employee[i].Active"))
' Load the CreateTime into a CkDateTime...
dtime.SetFromTimestamp(json.StringOf("QueryResponse.Employee[i].MetaData.CreateTime"))
dtime.ToDtObj(bLocalTime, dt)
Log(dt.Month & "/" & dt.Day & "/" & dt.Year & " " & dt.Hour & ":" & dt.Minute)
' The the birth year, month, and day, if it exists.
' The BirthDate contains something like this: "1985-09-11"
If json.HasMember("QueryResponse.Employee[i].BirthDate") = True Then
Dim sTab As ChilkatStringTable
sTab.Initialize
sTab.SplitAndAppend(json.StringOf("QueryResponse.Employee[i].BirthDate"), "-", True, True)
Dim year As String = sTab.StringAt(0)
Dim month As String = sTab.StringAt(1)
Dim day As String = sTab.StringAt(2)
Log("BirthDate: " & month & "/" & day & "/" & year)
End If
Log("----")
i = i + 1
Loop
Log("Success.")
' ------------------------------------------------------
' The JSON response looks like this:
' {
' "QueryResponse": {
' "Employee": [
' {
' "BillableTime": false,
' "domain": "QBO",
' "sparse": false,
' "Id": "55",
' "SyncToken": "0",
' "MetaData": {
' "CreateTime": "2016-09-15T11:21:48-07:00",
' "LastUpdatedTime": "2016-09-15T11:21:48-07:00"
' },
' "GivenName": "Emily",
' "FamilyName": "Platt",
' "DisplayName": "Emily Platt",
' "PrintOnCheckName": "Emily Platt",
' "Active": true
' },
' {
' "BillableTime": false,
' "BirthDate": "1985-09-11",
' "HiredDate": "2016-08-17",
' "domain": "QBO",
' "sparse": false,
' "Id": "54",
' "SyncToken": "1",
' "MetaData": {
' "CreateTime": "2016-09-15T11:21:28-07:00",
' "LastUpdatedTime": "2016-09-15T11:46:26-07:00"
' },
' "GivenName": "John",
' "FamilyName": "Johnson",
' "DisplayName": "John Johnson",
' "PrintOnCheckName": "John Johnson",
' "Active": true,
' "PrimaryPhone": {
' "FreeFormNumber": "(540) 555-9645"
' }
' },
' {
' "SSN": "XXX-XX-XXXX",
' "PrimaryAddr": {
' "Id": "98",
' "Line1": "45 N. Elm Street",
' "City": "Middlefield",
' "CountrySubDivisionCode": "CA",
' "PostalCode": "93242"
' },
' "BillableTime": false,
' "domain": "QBO",
' "sparse": false,
' "Id": "60",
' "SyncToken": "0",
' "MetaData": {
' "CreateTime": "2016-10-25T14:08:18-07:00",
' "LastUpdatedTime": "2016-10-25T14:08:18-07:00"
' },
' "GivenName": "John",
' "FamilyName": "Meuller",
' "DisplayName": "John Meuller",
' "PrintOnCheckName": "John Meuller",
' "Active": true,
' "PrimaryPhone": {
' "FreeFormNumber": "408-525-1234"
' }
' }
' ],
' "startPosition": 1,
' "maxResults": 3
' },
' "time": "2016-10-25T14:18:38.487-07:00"
' }