B4X
PEPPOL Document Validation

Demonstrates how to call a Web service to validate your PEPPOL documents according to the latest PEPPOL rules. The validation service requires UBL files.
Chilkat B4X Downloads

Download Chilkat for B4X
B4X
Dim success As Boolean = False

'  This example assumes the Chilkat HTTP API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  --------------------------------------------------------------------------------
'  Also see Chilkat's Online WSDL Code Generator
'  to generate code and SOAP Request and Response XML for each operation in a WSDL.
'  --------------------------------------------------------------------------------

Dim http As ChilkatHttp
http.Initialize("http")

'  We are sending the following POST:

'  POST /wsdvs HTTP/1.1
'  Host: peppol.helger.com
'  Content-Type: application/soap+xml; charset=utf-8
'  Content-Length: <length>
'  
'  <?xml version="1.0"?>
'  <S:Envelope xmlns:S="http://schemas.xmlsoap.org/soap/envelope/">
'  <S:Body>
'  <validateRequestInput xmlns="http://peppol.helger.com/ws/documentvalidationservice/201701/" VESID="eu.peppol.bis2:t10:3.3.0" displayLocale="en">
'  <XML>...ENTITY_ENCODED_INVOICE_XML_GOES_HERE...</XML>
'  </validateRequestInput>
'  </S:Body>
'  </S:Envelope>

'  Build the SOAP XML shown above.
'  First load the PEPPOL invoice that will be the data contained in the <XML>...</XML> SOAP element.
'  We are using the XML invoice obtained from https://github.com/austriapro/ebinterface-standards/blob/master/schemas/ebInterface5p0/samples/ebinterface_5p0_sample_ecosio.xml
Dim sbPeppolInvoiceXml As ChilkatStringBuilder
sbPeppolInvoiceXml.Initialize
success = sbPeppolInvoiceXml.LoadFile("qa_data/xml/peppol_invoice.xml", "utf-8")

Dim xml As ChilkatXml
xml.Initialize
xml.Tag = "S:Envelope"
xml.AddAttribute("xmlns:S", "http://schemas.xmlsoap.org/soap/envelope/")
xml.UpdateAttrAt("S:Body|validateRequestInput", True, "xmlns", "http://peppol.helger.com/ws/documentvalidationservice/201701/")
xml.UpdateAttrAt("S:Body|validateRequestInput", True, "VESID", "at.ebinterface:invoice:5.0")
xml.UpdateAttrAt("S:Body|validateRequestInput", True, "displayLocale", "en")
xml.UpdateChildContent("S:Body|validateRequestInput|XML", sbPeppolInvoiceXml.GetAsString)

'  We don't need to specify the Content-Length or Host headers.  Chilkat automatically adds them.

'  Send the request...
Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpStr("POST", "https://peppol.helger.com/wsdvs", xml.GetXml, "utf-8", "text/xml", resp)
If success = False Then
    Log(http.LastErrorText)
    Return
End If


Log("Response Status Code = " & resp.StatusCode)

Dim respXml As ChilkatXml
respXml.Initialize
respXml.LoadXml(resp.BodyStr)

Log("Response XML:")
Log(respXml.GetXml)

'  A success repsonse looks like this:

'  <?xml version="1.0" encoding="UTF-8"?>
'  <S:Envelope xmlns:S="http://schemas.xmlsoap.org/soap/envelope/">
'      <S:Body>
'          <validateResponseOutput xmlns="http://peppol.helger.com/ws/documentvalidationservice/201701/" success="true" interrupted="false" mostSevereErrorLevel="SUCCESS">
'              <Result success="true" artifactType="xsd" artifactPath="/schemas/ebinterface/ebinterface-5.0.xsd"/>
'          </validateResponseOutput>
'      </S:Body>
'  </S:Envelope>