B4X

PayPal - Generate Invoice Number

See more PayPal Examples

Generates the next invoice number that is available to the user.

Note: This example requires Chilkat v9.5.0.65 or greater.

B4X

Dim success As Boolean = False

'  Note: Requires Chilkat v9.5.0.65 or greater.

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  Load our previously obtained access token. (see PayPal OAuth2 Access Token)
Dim jsonToken As ChilkatJsonObject
jsonToken.Initialize
jsonToken.LoadFile("qa_data/tokens/paypal.json")

'  Build the Authorization request header field value.
Dim sbAuth As ChilkatStringBuilder
sbAuth.Initialize
'  token_type should be "Bearer"
sbAuth.Append(jsonToken.StringOf("token_type"))
sbAuth.Append(" ")
sbAuth.Append(jsonToken.StringOf("access_token"))

'  Make the initial connection.
'  A single REST object, once connected, can be used for many PayPal REST API calls.
'  The auto-reconnect indicates that if the already-established HTTPS connection is closed,
'  then it will be automatically re-established as needed.
Dim rest As ChilkatRest
rest.Initialize("rest")
Dim bAutoReconnect As Boolean = True
success = rest.Connect("api.sandbox.paypal.com", 443, True, bAutoReconnect)
If success <> True Then
    Log(rest.LastErrorText)
    Return
End If


'  ----------------------------------------------------------------------------------------------
'  The code above this comment could be placed inside a function/subroutine within the application
'  because the connection does not need to be made for every request.  Once the connection is made
'  the app may send many requests..
'  ----------------------------------------------------------------------------------------------

'  Clear the REST object of any headers or query params from previous requests.
rest.ClearAllHeaders
rest.ClearAllQueryParams

rest.AddHeader("Authorization", sbAuth.GetAsString)

'  Send the POST request with an emtpy body and get the JSON response.
Dim sbJsonRequest As ChilkatStringBuilder
sbJsonRequest.Initialize
Dim sbJsonResponse As ChilkatStringBuilder
sbJsonResponse.Initialize
success = rest.FullRequestSb("POST", "/v1/invoicing/invoices/next-invoice-number", sbJsonRequest, sbJsonResponse)
If success <> True Then
    Log(rest.LastErrorText)
    Return
End If


Dim json As ChilkatJsonObject
json.Initialize
json.EmitCompact = False
json.LoadSb(sbJsonResponse)

Log("Response Status Code = " & rest.ResponseStatusCode)

'  Did we get a 200 success response?
If rest.ResponseStatusCode <> 200 Then
    Log(json.Emit)
    Log("Failed.")
    Return
End If


'  Sample JSON response is shown below.
Log(json.Emit)
Log("----------------------")
Log("Next invoice number: " & json.StringOf("number"))
Log("success")

'  ------------------------------------------------
'  A sample JSON response:

'  	{ 
'  	  "number": "0003"
'  	}