B4X
B4X
PayPal - Create Direct Credit Card Payment
See more PayPal Examples
Creates a direct credit card payment where your application passes the credit card, shipping, and payment information to PayPal.Note: For sandbox calls, you can use the credit card numbers provided in your sandbox test accounts.
Note: This is an example where you handle the card data directly, and therefore you would need to ensure you are PCI compliant. There are other ways to create a payment where your application does NOT handle the credit card data directly.
Chilkat B4X Downloads
Dim success As Boolean = False
' Note: Requires Chilkat v9.5.0.64 or greater.
' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
' Load our previously obtained access token. (see PayPal OAuth2 Access Token)
Dim jsonToken As ChilkatJsonObject
jsonToken.Initialize
jsonToken.LoadFile("qa_data/tokens/paypal.json")
' Build the Authorization request header field value.
Dim sbAuth As ChilkatStringBuilder
sbAuth.Initialize
' token_type should be "Bearer"
sbAuth.Append(jsonToken.StringOf("token_type"))
sbAuth.Append(" ")
sbAuth.Append(jsonToken.StringOf("access_token"))
' Make the initial connection.
' A single REST object, once connected, can be used for many PayPal REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim rest As ChilkatRest
rest.Initialize("rest")
Dim bAutoReconnect As Boolean = True
success = rest.Connect("api.sandbox.paypal.com", 443, True, bAutoReconnect)
If success <> True Then
Log(rest.LastErrorText)
Return
End If
' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request. Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------
' Build the JSON containing the credit card data and transaction information.
Dim json As ChilkatJsonObject
json.Initialize
json.EmitCompact = False
json.UpdateString("intent", "sale")
json.UpdateString("payer.payment_method", "credit_card")
json.UpdateString("payer.funding_instruments[0].credit_card.number", "4032034813337237")
json.UpdateString("payer.funding_instruments[0].credit_card.type", "visa")
json.UpdateString("payer.funding_instruments[0].credit_card.expire_month", "9")
json.UpdateString("payer.funding_instruments[0].credit_card.expire_year", "2028")
json.UpdateString("payer.funding_instruments[0].credit_card.cvv2", "123")
json.UpdateString("transactions[0].amount.total", "10.00")
json.UpdateString("transactions[0].amount.currency", "USD")
json.UpdateString("transactions[0].payee.email", "payee@example.com")
' Use a sandbox CC number for testing:
' 
Log(json.Emit)
' The JSON created by the above code is this:
' -----------------------------------------------------------------
' Ensure that payee@example.com is a valid sandbox business account
' -----------------------------------------------------------------
' {
' "intent": "sale",
' "payer": {
' "payment_method": "credit_card",
' "funding_instruments": [
' {
' "credit_card": {
' "number": "4032034813337237",
' "type": "visa",
' "expire_month": "9",
' "expire_year": "2028",
' "cvv2": "123"
' }
' }
' ]
' },
' "transactions": [
' {
' "amount": {
' "total": "10.00",
' "currency": "USD"
' },
' "payee": {
' "email": "payee@example.com"
' }
' }
' ]
' }
rest.AddHeader("Authorization", sbAuth.GetAsString)
rest.AddHeader("Content-Type", "application/json")
' Send the POST request containign the JSON in the request body, and get the JSON response.
Dim sbJsonRequest As ChilkatStringBuilder
sbJsonRequest.Initialize
json.EmitCompact = True
json.EmitSb(sbJsonRequest)
Dim sbJsonResponse As ChilkatStringBuilder
sbJsonResponse.Initialize
success = rest.FullRequestSb("POST", "/v1/payments/payment", sbJsonRequest, sbJsonResponse)
If success <> True Then
Log(rest.LastErrorText)
Return
End If
json.EmitCompact = False
json.LoadSb(sbJsonResponse)
Log("Response Status Code = " & rest.ResponseStatusCode)
' Did we get a 201 success response?
If rest.ResponseStatusCode <> 201 Then
Log(json.Emit)
Log("Failed.")
Return
End If
' Sample response JSON is shown below.
Log(json.Emit)
' Demonstrate how to access a few parts of the JSON response..
Log("cc number: " & json.StringOf("payer.funding_instruments[0].credit_card.number"))
Log("subtotal: " & json.StringOf("transactions[0].amount.details.subtotal"))
Log("refund href: " & json.StringOf("transactions[0].related_resources[0].sale.links[1].href"))
' {
' "id": "PAY-66A12106PU3254228LA3BYKI",
' "create_time": "2016-11-23T22:46:01Z",
' "update_time": "2016-11-23T22:46:07Z",
' "state": "approved",
' "intent": "sale",
' "payer": {
' "payment_method": "credit_card",
' "funding_instruments": [
' {
' "credit_card": {
' "type": "visa",
' "number": "xxxxxxxxxxxx9974",
' "expire_month": "9",
' "expire_year": "2021",
' "first_name": "Joe",
' "last_name": "Buyer"
' }
' }
' ]
' },
' "transactions": [
' {
' "amount": {
' "total": "7.47",
' "currency": "USD",
' "details": {
' "subtotal": "7.47"
' }
' },
' "description": "This is the payment transaction description.",
' "related_resources": [
' {
' "sale": {
' "id": "70L88278E6781074B",
' "create_time": "2016-11-23T22:46:01Z",
' "update_time": "2016-11-23T22:46:07Z",
' "amount": {
' "total": "7.47",
' "currency": "USD"
' },
' "state": "completed",
' "parent_payment": "PAY-66A12106PU3254228LA3BYKI",
' "links": [
' {
' "href": "https://api.sandbox.paypal.com/v1/payments/sale/70L88278E6781074B",
' "rel": "self",
' "method": "GET"
' },
' {
' "href": "https://api.sandbox.paypal.com/v1/payments/sale/70L88278E6781074B/refund",
' "rel": "refund",
' "method": "POST"
' },
' {
' "href": "https://api.sandbox.paypal.com/v1/payments/payment/PAY-66A12106PU3254228LA3BYKI",
' "rel": "parent_payment",
' "method": "GET"
' }
' ],
' "fmf_details": {},
' "processor_response": {
' "avs_code": "X",
' "cvv_code": "M"
' }
' }
' }
' ]
' }
'
' ],
' "links": [
' {
' "href": "https://api.sandbox.paypal.com/v1/payments/payment/PAY-66A12106PU3254228LA3BYKI",
' "rel": "self",
' "method": "GET"
' }
' ]
' }
'