B4X

Create .p7s Compliant with ICP-Brazil Digital Signature Standard

Demonstrates how to create a .p7s signature that contains a data file, which in this case is a PDF. The .p7s will be compliant with the ICP-Brazil Digital Signature Standard.

Important: This example requires Chilkat v9.5.0.92 or later.

Chilkat B4X Downloads

Download Chilkat for B4X

B4X

Dim success As Boolean = False

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")

'  Any type of file can be signed.  It doesn't have to be a PDF.
Dim inFile As String = "qa_data/pdf/helloWorld.pdf"

Dim bd As ChilkatBinData
bd.Initialize
success = bd.LoadFile(inFile)
If success = False Then
    Log("Failed to load " & inFile)
    Return
End If


'  Get the certificate we'll be using to sign.
Dim cert As ChilkatCert
cert.Initialize("cert")

success = cert.LoadPfxFile("qa_data/pfx/cert_test123.pfx", "test123")
If success = False Then
    Log(cert.LastErrorText)
    Return
End If


success = crypt.SetSigningCert(cert)
If success = False Then
    Log(crypt.LastErrorText)
    Return
End If


'  Set properties for signing...
crypt.HashAlgorithm = "sha256"

Dim jsonSigningAttrs As ChilkatJsonObject
jsonSigningAttrs.Initialize
jsonSigningAttrs.UpdateInt("contentType", 1)
jsonSigningAttrs.UpdateInt("signingTime", 1)
jsonSigningAttrs.UpdateInt("messageDigest", 1)
jsonSigningAttrs.UpdateInt("signingCertificateV2", 1)

'  Listed here are the currently existing profiles. (Chilkat will add additional ICP Brasil policy profiles in future versions as new ones are created.)
'  See https://www.gov.br/iti/pt-br/assuntos/repositorio/artefatos-de-assinatura-digital for more information.
'  
'  PA_AD_RA --> 2.16.76.1.7.1.5.1
'  PA_AD_RA_v1_1 --> 2.16.76.1.7.1.5.1.1
'  PA_AD_RA_v1_2 --> 2.16.76.1.7.1.5.1.2
'  PA_AD_RA_v2_0 --> 2.16.76.1.7.1.5.2
'  PA_AD_RA_v2_1 --> 2.16.76.1.7.1.5.2.1
'  PA_AD_RA_v2_2 --> 2.16.76.1.7.1.5.2.2
'  PA_AD_RA_v2_3 --> 2.16.76.1.7.1.5.2.3
'  PA_AD_RA_v2_4 --> 2.16.76.1.7.1.5.2.4
'  PA_AD_RB --> 2.16.76.1.7.1.1.1
'  PA_AD_RB_v1_1 --> 2.16.76.1.7.1.1.1.1
'  PA_AD_RB_v2_0 --> 2.16.76.1.7.1.1.2
'  PA_AD_RB_v2_1 --> 2.16.76.1.7.1.1.2.1
'  PA_AD_RB_v2_2 --> 2.16.76.1.7.1.1.2.2
'  PA_AD_RB_v2_3 --> 2.16.76.1.7.1.1.2.3
'  PA_AD_RC --> 2.16.76.1.7.1.4.1
'  PA_AD_RC_v1_1 --> 2.16.76.1.7.1.4.1.1
'  PA_AD_RC_v2_0 --> 2.16.76.1.7.1.4.2
'  PA_AD_RC_v2_1 --> 2.16.76.1.7.1.4.2.1
'  PA_AD_RC_v2_2 --> 2.16.76.1.7.1.4.2.2
'  PA_AD_RC_v2_3 --> 2.16.76.1.7.1.4.2.3
'  PA_AD_RT --> 2.16.76.1.7.1.2.1
'  PA_AD_RT_v1_1 --> 2.16.76.1.7.1.2.1.1
'  PA_AD_RT_v2_0 --> 2.16.76.1.7.1.2.2
'  PA_AD_RT_v2_1 --> 2.16.76.1.7.1.2.2.1
'  PA_AD_RT_v2_2 --> 2.16.76.1.7.1.2.2.2
'  PA_AD_RT_v2_3 --> 2.16.76.1.7.1.2.2.3
'  PA_AD_RV --> 2.16.76.1.7.1.3.1
'  PA_AD_RV_v1_1 --> 2.16.76.1.7.1.3.1.1
'  PA_AD_RV_v2_0 --> 2.16.76.1.7.1.3.2
'  PA_AD_RV_v2_1 --> 2.16.76.1.7.1.3.2.1
'  PA_AD_RV_v2_2 --> 2.16.76.1.7.1.3.2.2
'  PA_AD_RV_v2_3 --> 2.16.76.1.7.1.3.2.3

'  Set the policy OID and the profile name
jsonSigningAttrs.UpdateString("policyId.id", "2.16.76.1.7.1.1.2.3")
jsonSigningAttrs.UpdateString("policyId.profile", "PA_AD_RB_v2_3")

crypt.SigningAttributes = jsonSigningAttrs.Emit

'  Sign. 
success = crypt.OpaqueSignBd(bd)
If success = False Then
    Log(crypt.LastErrorText)
    Return
End If


'  Save to a .p7s
success = bd.WriteFile("qa_output/helloWorld.pdf.p7s")

Log("Success")