B4X

MyInvois Malaysia Submit Document

See more Malaysia MyInvois Examples

Demonstrates how to submit a document to MyInvois. B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim http As ChilkatHttp
http.Initialize("http")

'  The following JSON is sent in the request body.

'  {
'    "documents": [
'      {
'        "format": "XML",
'        "documentHash": "<SHA256_hash_of_document>",
'        "codeNumber": "INV12345",
'        "document": "<Document_encoded_in_Base64>"
'      }
'    ]
'  }

'  Load the document to be sent.
Dim sbXmlDoc As ChilkatStringBuilder
sbXmlDoc.Initialize
success = sbXmlDoc.LoadFile("c:/invoices/invoice1.xml", "utf-8")

'  The MyInvois online documentation neglects to tell us the encoding of the documentHash.
'  Should it be base64?  Or hex?  We can only guess.  MyInvois provides no samples,
'  and omits these crucial details which are needed for actual implementation.
'  
'  *** Note: It was confirmed that "hex" is the encoding that is needed.
Dim sha256 As String = sbXmlDoc.GetHash("sha256", "hex", "utf-8")

Dim sbEncoded As ChilkatStringBuilder
sbEncoded.Initialize
sbEncoded.AppendSb(sbXmlDoc)
sbEncoded.Encode("base64", "utf-8")

Dim json As ChilkatJsonObject
json.Initialize
json.UpdateString("documents[0].format", "XML")
json.UpdateString("documents[0].documentHash", sha256)
json.UpdateString("documents[0].codeNumber", "INV12345")
json.UpdateSb("documents[0].document", sbEncoded)

'  Adds the "Authorization: Bearer <access_token>" header.
http.AuthToken = "<access_token>"

Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpJson("POST", "https://preprod-api.myinvois.hasil.gov.my/api/v1.0/documentsubmissions", json, "application/json", resp)
If success = False Then
    Log(http.LastErrorText)
    Return
End If


Log("response status code = " & resp.StatusCode)
Log(resp.BodyStr)