B4X

JWE with Binary Data

See more JSON Web Encryption (JWE) Examples

Demonstrates how to create a JWE that contains a binary payload (such as a JPG image).

Note: This example requires Chilkat v9.5.0.66 or greater.

B4X

Dim success As Boolean = False

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  Note: This example requires Chilkat v9.5.0.66 or greater.

'  Load a JPG file that will be the JWE payload.
Dim jpgBytes As ChilkatBinData
jpgBytes.Initialize
success = jpgBytes.LoadFile("qa_data/jpg/starfish.jpg")
'  Make sure your app checks the success/failure of the call to LoadFile..
Log("Original JPG size = " & jpgBytes.NumBytes)

Dim jwe As ChilkatJwe
jwe.Initialize

Dim jweProtHdr As ChilkatJsonObject
jweProtHdr.Initialize
jweProtHdr.AppendString("alg", "A128KW")
jweProtHdr.AppendString("enc", "A128CBC-HS256")
jwe.SetProtectedHeader(jweProtHdr)

Dim aesWrappingKey As String = "GawgguFyGrWKav7AX4VKUg"
jwe.SetWrappingKey(0, aesWrappingKey, "base64url")

'  Encrypt and return the JWE in sbJwe:
Dim sbJwe As ChilkatStringBuilder
sbJwe.Initialize
success = jwe.EncryptBd(jpgBytes, sbJwe)
If success <> True Then
    Log(jwe.LastErrorText)
    Return
End If


'  Show the JWE:
Log(sbJwe.GetAsString)
Log("size of JWE: " & sbJwe.Length)

'  ---------------------------------------------------------
'  Decrypt to get the original JPG file..

Dim jwe2 As ChilkatJwe
jwe2.Initialize
success = jwe2.LoadJweSb(sbJwe)
If success <> True Then
    Log(jwe2.LastErrorText)
    Return
End If

'  Set the AES wrap key.
jwe2.SetWrappingKey(0, aesWrappingKey, "base64url")

'  Decrypt.
Dim jpgOriginal As ChilkatBinData
jpgOriginal.Initialize
success = jwe2.DecryptBd(0, jpgOriginal)
If success <> True Then
    Log(jwe2.LastErrorText)
    Return
End If

Log("Decrypted JPG size = " & jpgOriginal.NumBytes)

'  Save the decrypted JPG to a file.
success = jpgOriginal.WriteFile("qa_output/jwe_decrypted_starfish.jpg")

Log("success = " & success)

'  The output of this program, when tested, was:
'  Original JPG size = 6229
'  eyJhbGciOiJBMTI4S1ciLCJlbmMiOiJBMTI4Q0JDLUhTMjU2In0.9YFz_wteV ... 7Et3hKhpxnKEXw
'  size of JWE: 8473
'  Decrypted JPG size = 6229
'  success = True