B4X

JSON: Nested Array

See more JSON Examples

Here we have a JSON object that contains nested arrays. This example demonstrates how to access the contents of the nested arrays.

{
 "numbers" : [ 
    ["even", 2, 4, 6, 8], 
    ["prime", 2, 3, 5, 7, 11, 13] 
  ] }

B4X

Dim success As Boolean = False

Dim json As ChilkatJsonObject
json.Initialize

'  This is the above JSON with whitespace chars removed (SPACE, TAB, CR, and LF chars).
'  The presence of whitespace chars for pretty-printing makes no difference to the Load
'  method. 
Dim jsonStr As String = "{ " & Chr(34) & "numbers" & Chr(34) & " : [ [" & Chr(34) & "even" & Chr(34) & ", 2, 4, 6, 8], [" & Chr(34) & "prime" & Chr(34) & ", 2, 3, 5, 7, 11, 13] ] }"

success = json.Load(jsonStr)
If success <> True Then
    Log(json.LastErrorText)
    Return
End If


'  Get the value of the "numbers" object, which is an array that contains JSON arrays.
Dim outerArray As ChilkatJsonArray = json.ArrayOf("numbers")
If json.LastMethodSuccess = False Then
    Log("numbers array not found.")
    Return
End If


Dim numArrays As Int = outerArray.Size
Dim i As Int

For i = 0 To numArrays - 1

    Dim innerArray As ChilkatJsonArray = outerArray.ArrayAt(i)

    '  The first item in the innerArray is a string
    Log(innerArray.StringAt(0) & ":")

    Dim numInnerItems As Int = innerArray.Size
    Dim j As Int
    For j = 1 To numInnerItems - 1

        Log("  " & innerArray.IntAt(j))

    Next


Next