B4X Requires Chilkat v11.0.0+

Convert Java KeyStore to PEM

See more Java KeyStore (JKS) Examples

Loads a Java keystore file and saves the trusted certificate entries to a PEM file. B4X

Dim success As Boolean = False

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim jks As ChilkatJavaKeyStore
jks.Initialize

Dim jksPassword As String = "myJksPassword"

'  Load the Java keystore from a file.  The JKS file password is used
'  to verify the keyed digest that is found at the very end of the keystore.
'  It verifies that the keystore has not been modified.
success = jks.LoadFile(jksPassword, "/someDir/keyStore.jks")
If success = False Then
    Log(jks.LastErrorText)
    Return
End If


'  Open/create the output PEM file. 
'  This example uses Chilkat's file access class for writing the output file.
'  You may replace the file I/O lines of code with whatever is most convenient for you.
Dim fac As ChilkatFileAccess
fac.Initialize
success = fac.OpenForWrite("/pemFiles/caCerts.pem")
If success = False Then
    Log(fac.LastErrorText)
    Return
End If


Dim numCerts As Int = jks.NumTrustedCerts

Dim cert As ChilkatCert
cert.Initialize("cert")
Dim pem As String

'  Iterate over the trusted certs, get the PEM for each,
'  and append it to the output file.
Dim i As Int = 0
Do While i < numCerts
    jks.TrustedCertAt(i, cert)

    '  Get the certificate in PEM format.  
    pem = cert.ExportCertPem

    '  Append the PEM string to the open file.
    success = fac.AppendText(pem, "utf-8")
    If success <> True Then
        Log(fac.LastErrorText)
        Return
    End If


    i = i + 1
Loop

'  Close the output file.
fac.FileClose

Log("Trusted certificates saved to PEM.")