B4X

IMAP Get Quota

Sends the GETQUOTA command to the IMAP server to get the quota information for a given quota root.

The GetQuota method is available in Chilkat starting at v9.5.0.58, and is only available for IMAP servers that support the QUOTA extension.

The information is returned in JSON format. This example demonstrates how to parse the JSON to get the desired information.

Typically, the quota root for the Inbox is the empty string. The GetQuotaRoot method can be called to get the quota root for a given mailbox.

B4X

Dim success As Boolean = False

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim imap As ChilkatImap
imap.Initialize("imap")

'  Use TLS
imap.Ssl = True
imap.Port = 993
success = imap.Connect("MY-IMAP-DOMAIN")
If success <> True Then
    Log(imap.LastErrorText)
    Return
End If


'  Authenticate
success = imap.Login("MY-IMAP-LOGIN", "MY-IMAP-PASSWORD")
If success <> True Then
    Log(imap.LastErrorText)
    Return
End If


'  First check to see if the IMAP server supports the QUOTA extension.
Dim caps As String = imap.Capability
If imap.LastMethodSuccess <> True Then
    Log(imap.LastErrorText)
    Return
End If


If imap.HasCapability("QUOTA", caps) <> True Then
    Log("IMAP server does not support the QUOTA extension.")
    Return
End If


'  This example assumes we already know the quota root for the given mailbox.
'  For Inbox, it is typically the empty string.  See the documentation and example 
'  for the GetQuotaRoot method to query for the quota root of a mailbox.  
'  (It's probably easier to use GetQuotaRoot because the mailbox name
'  can be passed to it, and in addition, it returns the quota information.)
'  method for details 
Dim jsonStr As String = imap.GetQuota("")
If imap.LastMethodSuccess <> True Then
    Log(imap.LastErrorText)
    Return
End If


'  The JSON string will look something like this:
'  {"QUOTA":{"root":"","resource":"STORAGE","used":22216,"max":15728640}}
Log(jsonStr)

'  This is easy to parse...
Dim json As ChilkatJsonObject
json.Initialize
json.Load(jsonStr)

'  Now get the resource name (which can be STORAGE or MESSAGE) and the used/max values.
'  Most servers have STORAGE quotas, which are for total capacity.  For example, GMail's
'  STORAGE quota is 15GB (at the time of writing this example).
'  A MESSAGE quota sets a limit on the number of messages.
Dim resourceName As String = json.StringOf("QUOTA.resource")
Dim quotaUsed As Int = json.IntOf("QUOTA.used")
Dim quotaMax As Int = json.IntOf("QUOTA.max")

Log("Resource: " & resourceName)
Log("Quota Used (in KB): " & quotaUsed)
Log("Quota Max (in KB): " & quotaMax)

'  Disconnect from the IMAP server.
success = imap.Disconnect