B4X Requires Chilkat v11.1.0+

Creating an application/json HTTP POST Request

See more HTTP Examples

Demonstrates how to create an HTTP POST request having the Content-Type application/json, where the body of the HTTP request is the following JSON:

{
   "username" : "my_username",
   "password" : "my_password",
   "validation-factors" : {
      "validationFactors" : [
         {
            "name" : "remote_address",
            "value" : "127.0.0.1"
         }
      ]
   }
}

The generated HTTP request looks like this:

POST /something HTTP/1.1
Content-Type: application/json
Accept: application/json
Host: domain
Content-Length: 216

{
  "username": "my_username",
  "password": "my_password",
  "validation-factors": {
    "validationFactors": [
      {
        "name": "remote_address",
        "value": "127.0.0.1"
      }
    ]
  }
}

B4X

'  This example demonstrates building an application/json request.

Dim req As ChilkatHttpRequest
req.Initialize

'  The ContentType, HttpVerb, and Path properties should
'  always be explicitly set.
req.HttpVerb = "POST"
req.Path = "/something"
req.ContentType = "application/json"

'  We may wish to add an "Accept" header to the request.
'  This tells the server we'll accept an application/json response.
req.AddHeader("Accept", "application/json")

'  We'll use Chilkat's JSON API to create the JSON body of the HTTP request.
Dim json As ChilkatJsonObject
json.Initialize
json.AppendString("username", "my_username")
json.AppendString("password", "my_password")

Dim vFactors As ChilkatJsonObject
vFactors.Initialize
json.AppendObject2("validation-factors", vFactors)

Dim vArray As ChilkatJsonArray
vArray.Initialize
vFactors.AppendArray2("validationFactors", vArray)

Dim factorObj As ChilkatJsonObject
factorObj.Initialize
vArray.AddObjectAt2(0, factorObj)
factorObj.AppendString("name", "remote_address")
factorObj.AppendString("value", "127.0.0.1")

'  Use the JSON for the HTTP request body
'  By default, the Emit method will output compact JSON.
'  This is best for generating the smallest size request.
'  To generate a more human-readable (pretty-printed) JSON request body,
'  set the EmitCompact property to FALSE
json.EmitCompact = False
req.LoadBodyFromString(json.Emit, "utf-8")

'  View the request that would be sent if HttpSReq was called:
Dim requestMime As String = req.GenerateRequestText
Log(requestMime)

'  A few important comments about the HTTP request that is generated:
'  
'  1) The Content-Length header is automatically generated based on the actual length of the MIME message
'     that follows the intial (topmost) MIME header.
'  2) The HOST header will automatically get filled in with the actual domain when HttpSReq
'     is called.