B4X

Resume an Interrupted FTP Transfer

Demonstrates the RestartNext and PartialTransfer properties, which request that the next transfer resume from existing content and report whether a download was incomplete.

Note: The local paths are relative to the application's current working directory. Absolute paths may also be used. Supply the paths appropriate to your own environment.

Background: For a large transfer over a flaky link, restarting from zero after a drop is wasteful. Setting RestartNext makes the next download continue from the current local file size (and the next upload from the remote size); the flag is consumed by that one transfer and then reset. Afterward PartialTransfer tells you whether the download got only part of the file — the signal to set RestartNext again and resume once more.

Chilkat B4X Downloads

Download Chilkat for B4X

B4X

Dim success As Boolean = False

Dim ftp As ChilkatFtp2
ftp.Initialize("ftp")

ftp.Hostname = "ftp.example.com"
ftp.Username = "myFtpLogin"

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
ftp.Password = "myPassword"

success = ftp.Connect
If success = False Then
    Log(ftp.LastErrorText)
    Return
End If


'  RestartNext requests that the NEXT transfer resume from existing content rather than starting
'  over.  It is consumed by that transfer and then automatically reset.
ftp.RestartNext = True

'  Resume a partially-downloaded file.  Because RestartNext is set, the download continues from
'  the current local file size.
success = ftp.GetFile("public_html/bigfile.zip", "qa_output/bigfile.zip")
If success = False Then
    Log(ftp.LastErrorText)
    Return
End If


'  PartialTransfer indicates whether the most recent download received some, but not all, of the
'  remote file -- distinguishing a mid-transfer failure from other outcomes.
If ftp.PartialTransfer Then
    Log("Only part of the file was received; another resume may be needed.")
Else
    Log("The file was fully received.")
End If


success = ftp.Disconnect
If success = False Then
    Log(ftp.LastErrorText)
    Return
End If