B4X Requires Chilkat v11.0.0+
B4X
Belgium eHealth Platform - checkAccessControl
See more Belgian eHealth Platform Examples
Demonstrates the checkAccessControl operation of PlatformIntegrationConsumerTest, which requires an X.509 certificate and signature. This tests the validity of your certificate and signature.Chilkat B4X Downloads
Dim success As Boolean = False
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
' Provide a certificate + private key.
' Note: If your certificate + private key is located on a hardware token or smartcard, you can call a different function to load from smartcard..
Dim cert As ChilkatCert
cert.Initialize("cert")
success = cert.LoadPfxFile("SSIN=12345678.acc.p12", "p12_password")
If success = False Then
Log(cert.LastErrorText)
Return
End If
' Create the XML to be signed...
Dim xmlToSign As ChilkatXml
xmlToSign.Initialize
xmlToSign.Tag = "soapenv:Envelope"
xmlToSign.AddAttribute("xmlns:soapenv", "http://schemas.xmlsoap.org/soap/envelope/")
xmlToSign.AddAttribute("xmlns:urn", "urn:be:fgov:ehealth:platformintegrationconsumertest:v1")
xmlToSign.AddAttribute("xmlns:urn1", "urn:be:fgov:ehealth:platformintegrationconsumertest:types:v1")
xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security", True, "xmlns:wsse", "http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd")
xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security", True, "xmlns:wsu", "http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-utility-1.0.xsd")
xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security|wsse:BinarySecurityToken", True, "EncodingType", "http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-soap-message-security-1.0#Base64Binary")
xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security|wsse:BinarySecurityToken", True, "ValueType", "http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-x509-token-profile-1.0#X509v3")
xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security|wsse:BinarySecurityToken", True, "wsu:Id", "X509-FC77E2C72083DA8E0F16711753508182856")
' ---------------------------------------------------------------------------------------------------------------
' A note about the Id's, such as X509-FC77E2C72083DA8E0F16711753508182856, TS-FC77E2C72083DA8E0F16711753508042855, etc.
' These Id's simply need to be unique within the XML document. You don't need to generate new Id's every time.
' You can use the same Id's in each XML document that is submitted. The purpose of each Id is to
' match the XMLDsig Reference to the element in XML being referenced.
' In other words, you could use the Id's "mickey_mouse", "donald_duck", and "goofy", and it would work perfectly OK,
' as long as no other XML elements also use the Id's "mickey_mouse", "donald_duck", or "goofy"
' ---------------------------------------------------------------------------------------------------------------
Dim bdCert As ChilkatBinData
bdCert.Initialize
cert.ExportCertDerBd(bdCert)
xmlToSign.UpdateChildContent("soapenv:Header|wsse:Security|wsse:BinarySecurityToken", bdCert.GetEncoded("base64"))
xmlToSign.UpdateAttrAt("soapenv:Header|wsse:Security|wsu:Timestamp", True, "wsu:Id", "TS-FC77E2C72083DA8E0F16711753508042855")
Dim dt As ChilkatDateTime
dt.Initialize
dt.SetFromCurrentSystemTime
xmlToSign.UpdateChildContent("soapenv:Header|wsse:Security|wsu:Timestamp|wsu:Created", dt.GetAsTimestamp(False))
dt.AddSeconds(3600)
xmlToSign.UpdateChildContent("soapenv:Header|wsse:Security|wsu:Timestamp|wsu:Expires", dt.GetAsTimestamp(False))
dt.AddSeconds(-3600)
xmlToSign.UpdateAttrAt("soapenv:Body", True, "wsu:Id", "id-FC77E2C72083DA8E0F16711753508182859")
xmlToSign.UpdateAttrAt("soapenv:Body", True, "xmlns:wsu", "http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-utility-1.0.xsd")
xmlToSign.UpdateChildContent("soapenv:Body|urn:CheckAccessControlRequest|urn1:Message", "Hello World")
' Create a timestamp with the current date/time in the following format: 2014-12-30T15:29:03.157+01:00
xmlToSign.UpdateChildContent("soapenv:Body|urn:CheckAccessControlRequest|urn1:Timestamp", dt.GetAsTimestamp(True))
Dim gen As ChilkatXmlDSigGen
gen.Initialize("gen")
gen.SigLocation = "soapenv:Envelope|soapenv:Header|wsse:Security|wsse:BinarySecurityToken"
gen.SigLocationMod = 1
gen.SigId = "SIG-FC77E2C72083DA8E0F16711753508252860"
gen.SigNamespacePrefix = "ds"
gen.SigNamespaceUri = "http://www.w3.org/2000/09/xmldsig#"
gen.SignedInfoPrefixList = "soapenv urn urn1"
gen.IncNamespacePrefix = "ec"
gen.IncNamespaceUri = "http://www.w3.org/2001/10/xml-exc-c14n#"
gen.SignedInfoCanonAlg = "EXCL_C14N"
gen.SignedInfoDigestMethod = "sha256"
' Set the KeyInfoId before adding references..
gen.KeyInfoId = "KI-FC77E2C72083DA8E0F16711753508182857"
' -------- Reference 1 --------
gen.AddSameDocRef("TS-FC77E2C72083DA8E0F16711753508042855", "sha256", "EXCL_C14N", "wsse soapenv urn urn1", "")
' -------- Reference 2 --------
gen.AddSameDocRef("id-FC77E2C72083DA8E0F16711753508182859", "sha256", "EXCL_C14N", "urn urn1", "")
' -------- Reference 3 --------
gen.AddSameDocRef("X509-FC77E2C72083DA8E0F16711753508182856", "sha256", "EXCL_C14N", "_EMPTY_", "")
gen.SetX509Cert(cert, True)
gen.KeyInfoType = "Custom"
' Create the custom KeyInfo XML..
Dim xmlCustomKeyInfo As ChilkatXml
xmlCustomKeyInfo.Initialize
xmlCustomKeyInfo.Tag = "wsse:SecurityTokenReference"
xmlCustomKeyInfo.AddAttribute("wsu:Id", "STR-FC77E2C72083DA8E0F16711753508182858")
xmlCustomKeyInfo.UpdateAttrAt("wsse:Reference", True, "URI", "#X509-FC77E2C72083DA8E0F16711753508182856")
xmlCustomKeyInfo.UpdateAttrAt("wsse:Reference", True, "ValueType", "http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-x509-token-profile-1.0#X509v3")
xmlCustomKeyInfo.EmitXmlDecl = False
gen.CustomKeyInfoXml = xmlCustomKeyInfo.GetXml
' Load XML to be signed...
Dim sbXml As ChilkatStringBuilder
sbXml.Initialize
xmlToSign.GetXmlSb(sbXml)
gen.Behaviors = "IndentedSignature"
' Sign the XML...
success = gen.CreateXmlDSigSb(sbXml)
If success = False Then
Log(gen.LastErrorText)
Return
End If
' -----------------------------------------------
' Send the signed XML...
Dim http As ChilkatHttp
http.Initialize("http")
success = http.SetSslClientCert(cert)
If success = False Then
Log(http.LastErrorText)
Return
End If
http.SetRequestHeader("Content-Type", "text/xml")
' Change to services.ehealth.fgov.be for the production environment.
Dim resp As ChilkatHttpResponse
resp.Initialize
success = http.HttpSb("POST", "https://services-acpt.ehealth.fgov.be/PlatformIntegrationConsumerTest/v1", sbXml, "utf-8", "application/xml", resp)
If success = False Then
Log(http.LastErrorText)
Return
End If
Log(resp.BodyStr)
Log("response status code = " & resp.StatusCode)
' A successful response is a 200 status code, with this sample response:
' <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
' <soapenv:Header xmlns:v1="urn:be:fgov:ehealth:platformintegrationconsumertest:v1" xmlns:v11="urn:be:fgov:ehealth:platformintegrationconsumertest:types:v1"/>
' <soapenv:Body xmlns:ic="urn:be:fgov:ehealth:platformintegrationconsumertest:v1" xmlns:type="urn:be:fgov:ehealth:platformintegrationconsumertest:types:v1">
' <ic:CheckAccessControlResponse>
' <type:Message>Hello World</type:Message>
' <type:Timestamp>2023-09-28T22:17:26.643+02:00</type:Timestamp>
' <type:AuthenticatedConsumer>CN="SSIN=aaaaaa", OU=eHealth-platform Belgium, OU=bbbb, OU="SSIN=aaaaaaa", O=Federal Government, C=BE</type:AuthenticatedConsumer>
' </ic:CheckAccessControlResponse>
' </soapenv:Body>
' </soapenv:Envelope>