B4X Requires Chilkat v11.0.0+

Generate ECDSA Key and Get Details as XML

See more ECC Examples

Demonstrates how to generate an ECDSA key and gets the parts as XML. B4X

Dim success As Boolean = False

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim ecc As ChilkatEcc
ecc.Initialize

'  Generate a random ECC private key on the secp256k1 curve.
'  Chilkat also supports other curves, such as secp384r1, secp521r1, and secp256r1.

'  Create a Fortuna PRNG and seed it with system entropy.
'  This will be our source of random data for generating the ECC private key.
Dim fortuna As ChilkatPrng
fortuna.Initialize
Dim entropy As String = fortuna.GetEntropy(32, "base64")
success = fortuna.AddEntropy(entropy, "base64")

Dim privKey As ChilkatPrivateKey
privKey.Initialize("privKey")
success = ecc.GenKey("secp256k1", fortuna, privKey)
If success = False Then
    Log(ecc.LastErrorText)
    Return
End If


'  An EC private key has this ASN.1
'  ECPrivateKey ::= SEQUENCE {
'      version        INTEGER { ecPrivkeyVer1(1) } (ecPrivkeyVer1),
'      privateKey     OCTET STRING,
'      parameters [0] ECParameters {{ NamedCurve }} OPTIONAL,
'      publicKey  [1] BIT STRING OPTIONAL (This is the ANSI X9.63 public key format.)

Dim asn As ChilkatAsn
asn.Initialize
success = asn.LoadEncoded(privKey.GetPkcs1ENC("base64"), "base64")
If success <> True Then
    Log(asn.LastErrorText)
    Return
End If


Dim xml As ChilkatXml
xml.Initialize
xml.LoadXml(asn.AsnToXml)

Log(xml.GetXml)

'  The XML looks like this:
'  <?xml version="1.0" encoding="utf-8" ?>
'  <sequence>
'      <int>01</int>
'      <octets>JgJvBG+3wletkJab8iXAkpz0O8/AgWZSpkYVcB7SpnU=</octets>
'      <contextSpecific tag="0" constructed="1">
'          <oid>1.3.132.0.10</oid>
'      </contextSpecific>
'  </sequence>

'  The 32-byte private key is in the octets..
'  Get it as hex.
Dim crypt As ChilkatCrypt2
crypt.Initialize("crypt")
Dim privKeyHex As String = crypt.ReEncode(xml.GetChildContent("octets"), "base64", "hex")

Log("EC private key as hex = " & privKeyHex)